02aaed54f6
Didn't bother to update the stable channel as it is unused currently. Changes required: * tazjin/frog, grfn/modules/obs: Remove obs-v4l2sink as it has been integrated into upstream OBS and the package removed from nixpkgs subsequently (at least according to the `builtins.throw`-message). Change-Id: I4335ed060eef2c4ff8ac55a68d894bcc3d8ef4a3 Reviewed-on: https://cl.tvl.fyi/c/depot/+/3243 Tested-by: BuildkiteCI Reviewed-by: grfn <grfn@gws.fyi> Reviewed-by: tazjin <mail@tazj.in>
61 lines
2.1 KiB
Nix
61 lines
2.1 KiB
Nix
# This file imports the pinned nixpkgs sets and applies relevant
|
|
# modifications, such as our overlays.
|
|
#
|
|
# Note that the attribute exposed by this (third_party.nixpkgs) is
|
|
# "special" in that the fixpoint used as readTree's config parameter
|
|
# in //default.nix passes this attribute as the `pkgs` argument to all
|
|
# readTree derivations.
|
|
|
|
{ depot, externalArgs, ... }:
|
|
|
|
let
|
|
# This provides the sources of nixpkgs. We track both
|
|
# nixos-unstable, and the current stable channel of the latest NixOS
|
|
# release.
|
|
|
|
# Tracking nixpkgs-unstable as of 2021-07-03.
|
|
unstableHashes = {
|
|
commit = "20887e4bbfdae3aed6bfa1f53ddf138ee325515e";
|
|
sha256 = "0hc79sv59appb7bynz5bzyqvrapyjdq63s79i649vxl93504kmnv";
|
|
};
|
|
|
|
# Tracking nixos-21.05 as of 2021-06-02.
|
|
stableHashes = {
|
|
commit = "eaba7870ffc3400eca4407baa24184b7fe337ec1";
|
|
sha256 = "115disiz4b08iw46cidc7lm0advrxn5g2ldmlrxd53zf03skyb2w";
|
|
};
|
|
|
|
# import the nixos-unstable package set, or optionally use the
|
|
# source (e.g. a path) specified by the `nixpkgsBisectPath`
|
|
# argument. This is intended for use-cases where the depot is
|
|
# bisected against nixpkgs to find the root cause of an issue in a
|
|
# channel bump.
|
|
nixpkgsSrc = externalArgs.nixpkgsBisectPath or (fetchTarball {
|
|
url = "https://github.com/NixOS/nixpkgs/archive/${unstableHashes.commit}.tar.gz";
|
|
sha256 = unstableHashes.sha256;
|
|
});
|
|
|
|
stableNixpkgsSrc = fetchTarball {
|
|
url = "https://github.com/NixOS/nixpkgs/archive/${stableHashes.commit}.tar.gz";
|
|
sha256 = stableHashes.sha256;
|
|
};
|
|
|
|
# Stable package set is imported, but not exposed, to overlay
|
|
# required packages into the unstable set.
|
|
stableNixpkgs = import stableNixpkgsSrc {};
|
|
|
|
# Overlay for packages that should come from the stable channel
|
|
# instead (e.g. because something is broken in unstable).
|
|
stableOverlay = self: super: {
|
|
# nothing picked from stable currently
|
|
};
|
|
in import nixpkgsSrc {
|
|
config.allowUnfree = true;
|
|
config.allowBroken = true;
|
|
overlays = [
|
|
stableOverlay
|
|
depot.third_party.overlays.tvl
|
|
depot.third_party.overlays.haskell
|
|
depot.third_party.overlays.emacs
|
|
];
|
|
}
|