e9061b11ab
Change-Id: Ic180b67c764e750d82c3bf4273216d7da75d3aaa Reviewed-on: https://cl.tvl.fyi/c/depot/+/3709 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org>
71 lines
2.4 KiB
Nix
71 lines
2.4 KiB
Nix
# This file imports the pinned nixpkgs sets and applies relevant
|
|
# modifications, such as our overlays.
|
|
#
|
|
# Note that the attribute exposed by this (third_party.nixpkgs) is
|
|
# "special" in that the fixpoint used as readTree's config parameter
|
|
# in //default.nix passes this attribute as the `pkgs` argument to all
|
|
# readTree derivations.
|
|
|
|
{ depot, externalArgs, ... }:
|
|
|
|
let
|
|
# This provides the sources of nixpkgs. We track both
|
|
# nixos-unstable, and the current stable channel of the latest NixOS
|
|
# release.
|
|
|
|
# Tracking nixos-unstable as of 2021-10-09.
|
|
unstableHashes = {
|
|
commit = "70088dc29994c32f8520150e34c6e57e8453f895";
|
|
sha256 = "08ldqfh2cmbvf930yq9pv220sv83k9shq183935l5d8p61fxh5zr";
|
|
};
|
|
|
|
# Tracking nixos-21.05 as of 2021-10-09.
|
|
stableHashes = {
|
|
commit = "ce7a1190a0fa4ba3465b5f5471b08567060ca14c";
|
|
sha256 = "1zr1s9gp0h5g4arlba1bpb9yqfaaby5195ydm6a2psaxhm748li9";
|
|
};
|
|
|
|
# import the nixos-unstable package set, or optionally use the
|
|
# source (e.g. a path) specified by the `nixpkgsBisectPath`
|
|
# argument. This is intended for use-cases where the depot is
|
|
# bisected against nixpkgs to find the root cause of an issue in a
|
|
# channel bump.
|
|
nixpkgsSrc = externalArgs.nixpkgsBisectPath or (fetchTarball {
|
|
url = "https://github.com/NixOS/nixpkgs/archive/${unstableHashes.commit}.tar.gz";
|
|
sha256 = unstableHashes.sha256;
|
|
});
|
|
|
|
stableNixpkgsSrc = fetchTarball {
|
|
url = "https://github.com/NixOS/nixpkgs/archive/${stableHashes.commit}.tar.gz";
|
|
sha256 = stableHashes.sha256;
|
|
};
|
|
|
|
# Stable package set is imported, but not exposed, to overlay
|
|
# required packages into the unstable set.
|
|
stableNixpkgs = import stableNixpkgsSrc {};
|
|
|
|
# Overlay for packages that should come from the stable channel
|
|
# instead (e.g. because something is broken in unstable).
|
|
stableOverlay = self: super: {
|
|
# Nothing picked from stable presently.
|
|
};
|
|
|
|
# Overlay to expose the nixpkgs commits we are using to other Nix code.
|
|
commitsOverlay = _: _: {
|
|
nixpkgsCommits = {
|
|
unstable = unstableHashes.commit;
|
|
stable = stableHashes.commit;
|
|
};
|
|
};
|
|
in import nixpkgsSrc {
|
|
config.allowUnfree = true;
|
|
config.allowBroken = true;
|
|
overlays = [
|
|
commitsOverlay
|
|
stableOverlay
|
|
depot.third_party.overlays.haskell
|
|
depot.third_party.overlays.emacs
|
|
depot.third_party.overlays.tvl
|
|
depot.third_party.overlays.ecl-static
|
|
];
|
|
}
|