aa122cbae7
This CL can be used to compare the style of nixpkgs-fmt against other formatters (nixpkgs, alejandra). Change-Id: I87c6abff6bcb546b02ead15ad0405f81e01b6d9e Reviewed-on: https://cl.tvl.fyi/c/depot/+/4397 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org> Reviewed-by: lukegb <lukegb@tvl.fyi> Reviewed-by: wpcarro <wpcarro@gmail.com> Reviewed-by: Profpatsch <mail@profpatsch.de> Reviewed-by: kanepyork <rikingcoding@gmail.com> Reviewed-by: tazjin <tazjin@tvl.su> Reviewed-by: cynthia <cynthia@tvl.fyi> Reviewed-by: edef <edef@edef.eu> Reviewed-by: eta <tvl@eta.st> Reviewed-by: grfn <grfn@gws.fyi>
32 lines
1.1 KiB
Nix
32 lines
1.1 KiB
Nix
{ lib, ... }:
|
|
let
|
|
# replaces " and \ to \" and \\ respectively and quote with "
|
|
# e.g.
|
|
# a"b\c -> "a\"b\\c"
|
|
# a\"bc -> "a\\\"bc"
|
|
escapeExeclineArg = arg:
|
|
''"${builtins.replaceStrings [ ''"'' ''\'' ] [ ''\"'' ''\\'' ] (toString arg)}"'';
|
|
|
|
# Escapes an execline (list of execline strings) to be passed to execlineb
|
|
# Give it a nested list of strings. Nested lists are interpolated as execline
|
|
# blocks ({}).
|
|
# Everything is quoted correctly.
|
|
#
|
|
# Example:
|
|
# escapeExecline [ "if" [ "somecommand" ] "true" ]
|
|
# == ''"if" { "somecommand" } "true"''
|
|
escapeExecline = execlineList: lib.concatStringsSep " "
|
|
(
|
|
let
|
|
go = arg:
|
|
if builtins.isString arg then [ (escapeExeclineArg arg) ]
|
|
else if builtins.isPath arg then [ (escapeExeclineArg "${arg}") ]
|
|
else if lib.isDerivation arg then [ (escapeExeclineArg arg) ]
|
|
else if builtins.isList arg then [ "{" ] ++ builtins.concatMap go arg ++ [ "}" ]
|
|
else abort "escapeExecline can only hande nested lists of strings, was ${lib.generators.toPretty {} arg}";
|
|
in
|
|
builtins.concatMap go execlineList
|
|
);
|
|
|
|
in
|
|
escapeExecline
|