7994fd1d54
git-subtree-dir: third_party/nix
git-subtree-mainline: cf8cd640c1
git-subtree-split: be66c7a6b24e3c3c6157fd37b86c7203d14acf10
41 lines
1.2 KiB
Nix
41 lines
1.2 KiB
Nix
{ system ? "" # obsolete
|
|
, url
|
|
, hash ? "" # an SRI ash
|
|
|
|
# Legacy hash specification
|
|
, md5 ? "", sha1 ? "", sha256 ? "", sha512 ? ""
|
|
, outputHash ?
|
|
if hash != "" then hash else if sha512 != "" then sha512 else if sha1 != "" then sha1 else if md5 != "" then md5 else sha256
|
|
, outputHashAlgo ?
|
|
if hash != "" then "" else if sha512 != "" then "sha512" else if sha1 != "" then "sha1" else if md5 != "" then "md5" else "sha256"
|
|
|
|
, executable ? false
|
|
, unpack ? false
|
|
, name ? baseNameOf (toString url)
|
|
}:
|
|
|
|
derivation {
|
|
builder = "builtin:fetchurl";
|
|
|
|
# New-style output content requirements.
|
|
inherit outputHashAlgo outputHash;
|
|
outputHashMode = if unpack || executable then "recursive" else "flat";
|
|
|
|
inherit name url executable unpack;
|
|
|
|
system = "builtin";
|
|
|
|
# No need to double the amount of network traffic
|
|
preferLocalBuild = true;
|
|
|
|
impureEnvVars = [
|
|
# We borrow these environment variables from the caller to allow
|
|
# easy proxy configuration. This is impure, but a fixed-output
|
|
# derivation like fetchurl is allowed to do so since its result is
|
|
# by definition pure.
|
|
"http_proxy" "https_proxy" "ftp_proxy" "all_proxy" "no_proxy"
|
|
];
|
|
|
|
# To make "nix-prefetch-url" work.
|
|
urls = [ url ];
|
|
}
|