2dbeaa80c3
A recent change in nixpkgs introduced evaluation warnings if a systemd service is configured to start after network-online.target, but does not directly depend on it. This is done because the existing dependency from multi-user.target to network-online.target is being removed, leaving these services without an actual dependency on the service. This affected autosubmit (I added a weak dependency here, for now the service is actually on the same host as Gerrit), and sterni's mirror setup (I added a strong dependency here). Change-Id: I88a4aa69f6788c489f59533d34be3c9cea681326 Reviewed-on: https://cl.tvl.fyi/c/depot/+/11026 Autosubmit: tazjin <tazjin@tvl.su> Reviewed-by: sterni <sternenseemann@systemli.org> Tested-by: BuildkiteCI
43 lines
1.2 KiB
Nix
43 lines
1.2 KiB
Nix
# Configuration for the Gerrit autosubmit bot (//ops/gerrit-autosubmit)
|
|
{ depot, pkgs, config, lib, ... }:
|
|
|
|
let
|
|
cfg = config.services.depot.gerrit-autosubmit;
|
|
description = "gerrit-autosubmit - autosubmit bot for Gerrit";
|
|
mkStringOption = default: lib.mkOption {
|
|
inherit default;
|
|
type = lib.types.str;
|
|
};
|
|
in
|
|
{
|
|
options.services.depot.gerrit-autosubmit = {
|
|
enable = lib.mkEnableOption description;
|
|
gerritUrl = mkStringOption "https://cl.tvl.fyi";
|
|
|
|
secretsFile = with lib; mkOption {
|
|
description = "Path to a systemd EnvironmentFile containing secrets";
|
|
default = config.age.secretsDir + "/gerrit-autosubmit";
|
|
type = types.str;
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
systemd.services.gerrit-autosubmit = {
|
|
inherit description;
|
|
wantedBy = [ "multi-user.target" ];
|
|
wants = [ "network-online.target" ];
|
|
after = [ "network-online.target" ];
|
|
|
|
serviceConfig = {
|
|
ExecStart = "${depot.ops.gerrit-autosubmit}/bin/gerrit-autosubmit";
|
|
DynamicUser = true;
|
|
Restart = "always";
|
|
EnvironmentFile = cfg.secretsFile;
|
|
};
|
|
|
|
environment = {
|
|
GERRIT_URL = cfg.gerritUrl;
|
|
};
|
|
};
|
|
};
|
|
}
|