a747b46f19
Reading through the changelogs, this includes the following two changes that may require us to do something: * For users of single-image Sourcegraph instance, please delete the secret key file /var/lib/sourcegraph/token inside the container before attempting to upgrade to 3.21.x. * A campaigns.restrictToAdmins site configuration option has been added to prevent non site-admin users from using campaigns. Change-Id: Ieacf85a9059ad5222800f8d7d4a43435f489a39f Reviewed-on: https://cl.tvl.fyi/c/depot/+/2638 Tested-by: BuildkiteCI Reviewed-by: tazjin <mail@tazj.in>
52 lines
1.4 KiB
Nix
52 lines
1.4 KiB
Nix
# Run sourcegraph, including its entire machinery, in a container.
|
|
# Running it outside of a container is a futile endeavour for now.
|
|
{ config, pkgs, lib, ... }:
|
|
|
|
let
|
|
cfg = config.services.depot.sourcegraph;
|
|
depot = config.depot;
|
|
in {
|
|
options.services.depot.sourcegraph = with lib; {
|
|
enable = mkEnableOption "SourceGraph code search engine";
|
|
|
|
port = mkOption {
|
|
description = "Port on which SourceGraph should listen";
|
|
type = types.int;
|
|
default = 3463;
|
|
};
|
|
|
|
cheddarPort = mkOption {
|
|
description = "Port on which cheddar should listen";
|
|
type = types.int;
|
|
default = 4238;
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
# Run a cheddar syntax highlighting server
|
|
systemd.services.cheddar-server = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
script = "${depot.tools.cheddar}/bin/cheddar --listen 0.0.0.0:${toString cfg.cheddarPort} --sourcegraph-server";
|
|
|
|
serviceConfig = {
|
|
DynamicUser = true;
|
|
Restart = "always";
|
|
};
|
|
};
|
|
|
|
virtualisation.oci-containers.containers.sourcegraph = {
|
|
image = "sourcegraph/server:3.26.0";
|
|
|
|
ports = [
|
|
"127.0.0.1:${toString cfg.port}:7080"
|
|
];
|
|
|
|
volumes = [
|
|
"/var/lib/sourcegraph/etc:/etc/sourcegraph"
|
|
"/var/lib/sourcegraph/data:/var/opt/sourcegraph"
|
|
];
|
|
|
|
environment.SRC_SYNTECT_SERVER = "http://172.17.0.1:${toString cfg.cheddarPort}";
|
|
};
|
|
};
|
|
}
|