4d5fdb781d
* //users/grfn/system/home/modules: The MultiMC saga continues with: > PolyMC has been removed from nixpkgs due to a hostile takeover > by a rogue maintainer. The rest of the maintainers have made a > fork which is packaged as 'prismlauncher'. * //third_party/overlays: Override tdlib to 1.8.7 while waiting for nixpkgs to catch up. * //users/tazjin/finito: Disable on CI temporarily as it has been broken by some change in nixpkgs, now failing to compile a dependency. Change-Id: Ide038a8d466bfdc19dc9016beb03ae4817939a2b Reviewed-on: https://cl.tvl.fyi/c/depot/+/7066 Reviewed-by: tazjin <tazjin@tvl.su> Reviewed-by: grfn <grfn@gws.fyi> Autosubmit: sterni <sternenseemann@systemli.org> Tested-by: BuildkiteCI
61 lines
1.6 KiB
Nix
61 lines
1.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with pkgs;
|
|
with lib;
|
|
|
|
let
|
|
|
|
df-orig = dwarf-fortress-packages.dwarf-fortress-original;
|
|
|
|
df-full = (dwarf-fortress-packages.dwarf-fortress-full.override {
|
|
theme = null;
|
|
enableIntro = false;
|
|
enableFPS = true;
|
|
enableDFHack = false; # Fails to build currently
|
|
});
|
|
|
|
init = runCommand "init.txt" { } ''
|
|
substitute "${df-orig}/data/init/init.txt" $out \
|
|
--replace "[INTRO:YES]" "[INTRO:NO]" \
|
|
--replace "[VOLUME:255]" "[VOLUME:0]" \
|
|
--replace "[FPS:NO]" "[FPS:YES]"
|
|
'';
|
|
|
|
d_init = runCommand "d_init.txt" { } ''
|
|
substitute "${df-orig}/data/init/d_init.txt" $out \
|
|
--replace "[AUTOSAVE:NONE]" "[AUTOSAVE:SEASONAL]" \
|
|
--replace "[AUTOSAVE_PAUSE:NO]" "[AUTOSAVE_PAUSE:YES]" \
|
|
--replace "[INITIAL_SAVE:NO]" "[INITIAL_SAVE:YES]" \
|
|
--replace "[EMBARK_WARNING_ALWAYS:NO]" "[EMBARK_WARNING_ALWAYS:YES]" \
|
|
--replace "[VARIED_GROUND_TILES:YES]" "[VARIED_GROUND_TILES:NO]" \
|
|
--replace "[SHOW_FLOW_AMOUNTS:NO]" "[SHOW_FLOW_AMOUNTS:YES]"
|
|
'';
|
|
|
|
df = runCommand "dwarf-fortress" { } ''
|
|
mkdir -p $out/bin
|
|
sed \
|
|
-e '4icp -f ${init} "$DF_DIR/data/init/init.txt"' \
|
|
-e '4icp -f ${d_init} "$DF_DIR/data/init/d_init.txt"' \
|
|
< "${df-full}/bin/dwarf-fortress" >"$out/bin/dwarf-fortress"
|
|
|
|
shopt -s extglob
|
|
ln -s ${df-full}/bin/!(dwarf-fortress) $out/bin
|
|
|
|
chmod +x $out/bin/dwarf-fortress
|
|
'';
|
|
|
|
in
|
|
mkMerge [
|
|
{
|
|
home.packages = [
|
|
crawl
|
|
xonotic
|
|
];
|
|
}
|
|
(mkIf stdenv.isLinux {
|
|
home.packages = [
|
|
df
|
|
prismlauncher
|
|
];
|
|
})
|
|
]
|