c2a5073339
This adds a little tool that can be used to relay mail to Gmail (and other SMTP servers). It is intended to be used by Gerrit, which is incompatible with Gmail's SMTP servers. Configuration has been tested by performing a few sends through the tvlbot@tazj.in account. Note that this is using the standard Gmail SMTP server. Using the smtp-relay server relies on IP whitelisting, but camden.tazj.in has a larger number of IPv6 addresses than can be whitelisted (the maximum is 65k). This means that we are limited to 2000 mails per recipient per day, which should be fine. Change-Id: Ie43564d753030f5c800a9cdb4ae98292877d80dc Reviewed-on: https://cl.tvl.fyi/c/depot/+/101 Reviewed-by: edef <edef@edef.eu>
52 lines
1.4 KiB
Nix
52 lines
1.4 KiB
Nix
# NixOS module for configuring the simple SMTP relay.
|
|
{ pkgs, config, lib, ... }:
|
|
|
|
let
|
|
inherit (builtins) attrValues mapAttrs;
|
|
inherit (lib)
|
|
concatStringsSep
|
|
mkEnableOption
|
|
mkOption
|
|
types
|
|
;
|
|
|
|
cfg = config.services.depot.smtprelay;
|
|
description = "Simple SMTP relay";
|
|
|
|
# Configuration values that are always overridden. In particular,
|
|
# `config` is specified to always load $StateDirectory/secure.config
|
|
# (so that passwords can be loaded from there) and logging is pinned
|
|
# to stdout for journald compatibility.
|
|
overrideArgs = {
|
|
logfile = "";
|
|
config = "/var/lib/smtprelay/secure.config";
|
|
};
|
|
|
|
# Creates the command line argument string for the service.
|
|
prepareArgs = args:
|
|
concatStringsSep " "
|
|
(attrValues (mapAttrs (key: value: "-${key} '${toString value}'")
|
|
(args // overrideArgs)));
|
|
in {
|
|
options.services.depot.smtprelay = {
|
|
enable = mkEnableOption description;
|
|
args = mkOption {
|
|
type = types.attrsOf types.str;
|
|
description = "Key value pairs for command line arguments";
|
|
};
|
|
};
|
|
|
|
config = {
|
|
systemd.services.smtprelay = {
|
|
inherit description;
|
|
script = "${config.depot.third_party.smtprelay}/bin/smtprelay ${prepareArgs cfg.args}";
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = {
|
|
Restart = "always";
|
|
StateDirectory = "smtprelay";
|
|
DynamicUser = true;
|
|
};
|
|
};
|
|
};
|
|
}
|