02ee441626
This bumps bigtable_rs to https://github.com/liufuyang/bigtable_rs/pull/86, allowing us to drop our second set of prost/tonic/http/axum crates. Change-Id: I70f9150289c3e8611ebe8a7d99490e3dfd085a6e Reviewed-on: https://cl.tvl.fyi/c/depot/+/12384 Tested-by: BuildkiteCI Reviewed-by: Connor Brewster <cbrewster@hey.com> Autosubmit: flokli <flokli@flokli.de>
127 lines
3.3 KiB
Nix
127 lines
3.3 KiB
Nix
# Nix helpers for projects under //tvix
|
|
{ pkgs, lib, depot, ... }:
|
|
|
|
let
|
|
# Load the crate2nix crate tree.
|
|
crates = pkgs.callPackage ./Cargo.nix {
|
|
defaultCrateOverrides = depot.tvix.utils.defaultCrateOverridesForPkgs pkgs;
|
|
};
|
|
|
|
# Cargo dependencies to be used with nixpkgs rustPlatform functions.
|
|
cargoDeps = pkgs.rustPlatform.importCargoLock {
|
|
lockFile = ./Cargo.lock;
|
|
# Extract the hashes from `crates` / Cargo.nix, we already get them from cargo2nix.
|
|
# This returns an attribute set containing "${crateName}-${version}" as key,
|
|
# and the outputHash as value.
|
|
outputHashes = builtins.listToAttrs
|
|
(map
|
|
(k:
|
|
(lib.nameValuePair "${crates.internal.crates.${k}.crateName}-${crates.internal.crates.${k}.version}" crates.internal.crates.${k}.src.outputHash)
|
|
) [
|
|
"bigtable_rs"
|
|
"wu-manber"
|
|
]);
|
|
};
|
|
|
|
# The cleaned sources.
|
|
src = depot.third_party.gitignoreSource ./.;
|
|
|
|
# Target containing *all* tvix proto files.
|
|
# Useful for workspace-wide cargo invocations (doc, clippy)
|
|
protos = pkgs.symlinkJoin {
|
|
name = "tvix-all-protos";
|
|
paths = [
|
|
depot.tvix.build.protos.protos
|
|
depot.tvix.castore.protos.protos
|
|
depot.tvix.store.protos.protos
|
|
];
|
|
};
|
|
|
|
in
|
|
{
|
|
inherit crates protos;
|
|
|
|
# Provide the Tvix logo in both .webp and .png format.
|
|
logo = pkgs.runCommand "logo"
|
|
{
|
|
nativeBuildInputs = [ pkgs.imagemagick ];
|
|
} ''
|
|
mkdir -p $out
|
|
cp ${./logo.webp} $out/logo.webp
|
|
convert $out/logo.webp $out/logo.png
|
|
'';
|
|
|
|
# Provide a shell for the combined dependencies of all Tvix Rust
|
|
# projects. Note that as this is manually maintained it may be
|
|
# lacking something, but it is required for some people's workflows.
|
|
#
|
|
# This shell can be entered with e.g. `mg shell //tvix:shell`.
|
|
# This is a separate file, so it can be used individually in the tvix josh
|
|
# workspace too.
|
|
shell = (import ./shell.nix { inherit pkgs; });
|
|
|
|
# Build the Rust documentation for publishing on docs.tvix.dev.
|
|
rust-docs = pkgs.stdenv.mkDerivation {
|
|
inherit cargoDeps src;
|
|
name = "tvix-rust-docs";
|
|
PROTO_ROOT = protos;
|
|
|
|
nativeBuildInputs = with pkgs; [
|
|
cargo
|
|
pkg-config
|
|
protobuf
|
|
rustc
|
|
rustPlatform.cargoSetupHook
|
|
];
|
|
|
|
buildInputs = [
|
|
pkgs.fuse
|
|
] ++ lib.optional pkgs.stdenv.isDarwin pkgs.libiconv;
|
|
|
|
buildPhase = ''
|
|
cargo doc --document-private-items
|
|
mv target/doc $out
|
|
'';
|
|
};
|
|
|
|
# Run cargo clippy. We run it with -Dwarnings, so warnings cause a nonzero
|
|
# exit code.
|
|
clippy = pkgs.stdenv.mkDerivation {
|
|
inherit cargoDeps src;
|
|
name = "tvix-clippy";
|
|
PROTO_ROOT = protos;
|
|
|
|
buildInputs = [
|
|
pkgs.fuse
|
|
];
|
|
nativeBuildInputs = with pkgs; [
|
|
cargo
|
|
clippy
|
|
pkg-config
|
|
protobuf
|
|
rustc
|
|
rustPlatform.cargoSetupHook
|
|
];
|
|
|
|
buildPhase = "cargo clippy --tests --all-features --benches --examples -- -Dwarnings | tee $out";
|
|
};
|
|
|
|
crate2nix-check =
|
|
let
|
|
crate2nix-check = depot.tvix.utils.mkCrate2nixCheck ./Cargo.nix;
|
|
in
|
|
crate2nix-check.command.overrideAttrs {
|
|
meta.ci.extraSteps = {
|
|
inherit crate2nix-check;
|
|
};
|
|
};
|
|
|
|
meta.ci.targets = [
|
|
"clippy"
|
|
"shell"
|
|
"rust-docs"
|
|
"crate2nix-check"
|
|
];
|
|
|
|
utils = import ./utils.nix { inherit pkgs lib depot; };
|
|
}
|