f50800a9df
Using an actual store path here means we have to copy all of depot into the Nix store just to rebuild NixOS for a system - this is especially painful if, like me, you have a rust target/ directory in depot which is hundreds of GB - nix-build just OOMed on my system with 128GB of RAM! There's no reason to use a store path here - we can just point to wherever depot happened to be cloned. Change-Id: Ibfd7181f0f75de077561db70ac8636389836980f Reviewed-on: https://cl.tvl.fyi/c/depot/+/10997 Reviewed-by: sterni <sternenseemann@systemli.org> Reviewed-by: tazjin <tazjin@tvl.su> Autosubmit: aspen <root@gws.fyi> Tested-by: BuildkiteCI
67 lines
2.2 KiB
Nix
67 lines
2.2 KiB
Nix
# Helper functions for instantiating depot-compatible NixOS machines.
|
|
{ depot, lib, pkgs, ... }@args:
|
|
|
|
let inherit (lib) findFirst isAttrs;
|
|
in rec {
|
|
# This provides our standard set of arguments to all NixOS modules.
|
|
baseModule = { ... }: {
|
|
# Ensure that pkgs == third_party.nix
|
|
nixpkgs.pkgs = depot.third_party.nixpkgs;
|
|
nix.nixPath =
|
|
let
|
|
# Due to nixpkgsBisectPath, pkgs.path is not always in the nix store
|
|
nixpkgsStorePath =
|
|
if lib.hasPrefix builtins.storeDir (toString pkgs.path)
|
|
then builtins.storePath pkgs.path # nixpkgs is already in the store
|
|
else pkgs.path; # we need to dump nixpkgs to the store either way
|
|
in
|
|
[
|
|
("nixos=" + nixpkgsStorePath)
|
|
("nixpkgs=" + nixpkgsStorePath)
|
|
];
|
|
};
|
|
|
|
nixosFor = configuration: (depot.third_party.nixos {
|
|
configuration = { ... }: {
|
|
imports = [
|
|
baseModule
|
|
configuration
|
|
];
|
|
};
|
|
|
|
specialArgs = {
|
|
inherit (args) depot;
|
|
};
|
|
});
|
|
|
|
findSystem = hostname:
|
|
(findFirst
|
|
(system: system.config.networking.hostName == hostname)
|
|
(throw "${hostname} is not a known NixOS host")
|
|
(map nixosFor depot.ops.machines.all-systems));
|
|
|
|
rebuild-system = rebuildSystemWith (
|
|
# HACK: use the string of the original source to avoid copying the whole
|
|
# depot into the store just for this
|
|
builtins.toString depot.path.origSrc);
|
|
|
|
rebuildSystemWith = depotPath: pkgs.writeShellScriptBin "rebuild-system" ''
|
|
set -ue
|
|
if [[ $EUID -ne 0 ]]; then
|
|
echo "Oh no! Only root is allowed to rebuild the system!" >&2
|
|
exit 1
|
|
fi
|
|
|
|
echo "Rebuilding NixOS for $HOSTNAME"
|
|
system=$(${pkgs.nix}/bin/nix-build -E "((import ${depotPath} {}).ops.nixos.findSystem \"$HOSTNAME\").system" --no-out-link --show-trace)
|
|
|
|
${pkgs.nix}/bin/nix-env -p /nix/var/nix/profiles/system --set $system
|
|
$system/bin/switch-to-configuration switch
|
|
'';
|
|
|
|
# Systems that should be built in CI
|
|
whitbySystem = (nixosFor depot.ops.machines.whitby).system;
|
|
sandunySystem = (nixosFor depot.ops.machines.sanduny).system;
|
|
nixeryDev01System = (nixosFor depot.ops.machines.nixery-01).system;
|
|
meta.ci.targets = [ "sandunySystem" "whitbySystem" "nixeryDev01System" ];
|
|
}
|