1c16dee207
This makes reqwest honor `SSL_CERT_FILE` - previously it was using the chain bundled in webpki-roots. `object_store` pulls in `reqwest` with this feature, and the cargo solver will enable that feature globally as soon as we pull it in, as it assumes features are additive. This requires setting `SSL_CERT_FILE` when running tests, otherwise they'll fail with the unhelpful "NotFound" error. This was quite some fun to debug, why adding `object_store` to tvix-castore suddenly made tvix-store tests fail! Change-Id: I64fc82b4d994715480efdb1ffecb279716456ab9 Reviewed-on: https://cl.tvl.fyi/c/depot/+/11090 Reviewed-by: raitobezarius <tvl@lahfa.xyz> Tested-by: BuildkiteCI
38 lines
1.2 KiB
Nix
38 lines
1.2 KiB
Nix
{ depot, pkgs, ... }:
|
|
|
|
let
|
|
mkImportCheck = p: expectedPath: {
|
|
label = ":nix :import ${p} with tvix-store import";
|
|
needsOutput = true;
|
|
command = pkgs.writeShellScript "tvix-import-check" ''
|
|
export BLOB_SERVICE_ADDR=memory://
|
|
export DIRECTORY_SERVICE_ADDR=memory://
|
|
export PATH_INFO_SERVICE_ADDR=memory://
|
|
TVIX_STORE_OUTPUT=$(result/bin/tvix-store import ${p})
|
|
EXPECTED='${/* the vebatim expected Tvix output: */expectedPath}'
|
|
|
|
echo "tvix-store output: ''${TVIX_STORE_OUTPUT}"
|
|
if [ "$TVIX_STORE_OUTPUT" != "$EXPECTED" ]; then
|
|
echo "Correct would have been ''${EXPECTED}"
|
|
exit 1
|
|
fi
|
|
|
|
echo "Output was correct."
|
|
'';
|
|
};
|
|
in
|
|
|
|
(depot.tvix.crates.workspaceMembers.tvix-store.build.override {
|
|
runTests = true;
|
|
testPreRun = ''
|
|
export SSL_CERT_FILE=${pkgs.cacert}/etc/ssl/certs/ca-bundle.crt;
|
|
'';
|
|
|
|
# virtiofs feature currently fails to build on Darwin.
|
|
# we however can ship it for non-darwin.
|
|
features = if pkgs.stdenv.isDarwin then [ "default" ] else [ "default" "virtiofs" ];
|
|
}).overrideAttrs (_: {
|
|
meta.ci.extraSteps = {
|
|
import-docs = (mkImportCheck "tvix/store/docs" ./docs);
|
|
};
|
|
})
|