4b2f3c5454
See https://github.com/NixOS/nixpkgs/pull/323753 for details. Changes: * git: temporarily comment out dottime patch (it doesn't apply, but it's not critical) * third-party/cgit: use an older git version where dottime patch still applies * 3p/crate2nix: remove crate2nix patches included in latest release * tvix: remove unneeded defaultCrateOverrides (upstreamed to nixpkgs) * tvix: regenerate Cargo.nix * tvix/nix-compat: remove unnused AtermWriteable::aterm_bytes pub(crate) function * tvix/nix-compat: remove redundant trait bounds * tvix/glue: use clone_into() to set drv.{builder,system} * tools/crate2nix: apply workaround for https://github.com/numtide/treefmt/issues/327 * toold/depotfmt: expose treefmt config as passthru * tools/crate2nix: undo some more hacks in the crate2nix-check drv Change-Id: Ifbcedeb3e8f81b2f6ec1dbf10189bfa6dfd9c75c Co-Authored-By: Florian Klink <flokli@flokli.de> Reviewed-on: https://cl.tvl.fyi/c/depot/+/11907 Reviewed-by: tazjin <tazjin@tvl.su> Tested-by: BuildkiteCI Reviewed-by: flokli <flokli@flokli.de>
62 lines
1.6 KiB
Nix
62 lines
1.6 KiB
Nix
# Builds treefmt for depot, with a hardcoded configuration that
|
|
# includes the right paths to formatters.
|
|
{ depot, pkgs, ... }:
|
|
|
|
let
|
|
# terraform fmt can't handle multiple paths at once, but treefmt
|
|
# expects this
|
|
terraformat = pkgs.writeShellScript "terraformat" ''
|
|
echo "$@" | xargs -n1 ${pkgs.terraform}/bin/terraform fmt
|
|
'';
|
|
|
|
config = pkgs.writeText "depot-treefmt-config" ''
|
|
[formatter.go]
|
|
command = "${depot.nix.buildGo.go}/bin/gofmt"
|
|
options = [ "-w" ]
|
|
includes = ["*.go"]
|
|
|
|
[formatter.tf]
|
|
command = "${terraformat}"
|
|
includes = [ "*.tf" ]
|
|
|
|
[formatter.nix]
|
|
command = "${pkgs.nixpkgs-fmt}/bin/nixpkgs-fmt"
|
|
includes = [ "*.nix" ]
|
|
excludes = [
|
|
"tvix/eval/src/tests/nix_tests/*",
|
|
]
|
|
|
|
[formatter.rust]
|
|
command = "${pkgs.rustfmt}/bin/rustfmt"
|
|
includes = [ "*.rs" ]
|
|
excludes = [
|
|
"users/tazjin/*",
|
|
]
|
|
'';
|
|
|
|
# helper tool for formatting the depot interactively
|
|
depotfmt = pkgs.writeShellScriptBin "depotfmt" ''
|
|
exec ${pkgs.treefmt}/bin/treefmt ''${@} \
|
|
--on-unmatched=debug \
|
|
--config-file=${config} \
|
|
--tree-root $(${pkgs.git}/bin/git rev-parse --show-toplevel)
|
|
'';
|
|
|
|
# wrapper script for running formatting checks in CI
|
|
check = pkgs.writeShellScript "depotfmt-check" ''
|
|
${pkgs.treefmt}/bin/treefmt \
|
|
--no-cache \
|
|
--on-unmatched=debug \
|
|
--fail-on-change \
|
|
--config-file=${config} \
|
|
--tree-root=.
|
|
'';
|
|
in
|
|
depotfmt.overrideAttrs (_: {
|
|
passthru.config = config;
|
|
passthru.meta.ci.extraSteps.check = {
|
|
label = "depot formatting check";
|
|
command = check;
|
|
alwaysRun = true;
|
|
};
|
|
})
|