844cf6a794
This removes *all* of `struct.el`'s dependencies, which is liberating. Change-Id: Ic4a2438714ecf547ba5e07a1f0e77d743941073c Reviewed-on: https://cl.tvl.fyi/c/depot/+/6029 Tested-by: BuildkiteCI Reviewed-by: wpcarro <wpcarro@gmail.com> Autosubmit: wpcarro <wpcarro@gmail.com>
65 lines
2 KiB
EmacsLisp
65 lines
2 KiB
EmacsLisp
;;; struct.el --- Helpers for working with structs -*- lexical-binding: t -*-
|
|
|
|
;; Author: William Carroll <wpcarro@gmail.com>
|
|
;; Version: 1.0.0
|
|
;; Package-Requires: ((emacs "24.3"))
|
|
|
|
;;; Commentary:
|
|
;; Provides new macros for working with structs. Also provides adapter
|
|
;; interfaces to existing struct macros, that should have more intuitive
|
|
;; interfaces.
|
|
;;
|
|
;; Sometimes `setf' just isn't enough.
|
|
|
|
;;; Code:
|
|
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;; Library
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
|
|
(defmacro struct-update (type field f xs)
|
|
"Apply F to FIELD in XS, which is a struct of TYPE.
|
|
This is immutable."
|
|
(let ((copier (struct--copier-for type))
|
|
(accessor (struct--accessor-for type field)))
|
|
`(let ((copy (,copier ,xs)))
|
|
(setf (,accessor copy) (funcall ,f (,accessor copy)))
|
|
copy)))
|
|
|
|
(defmacro struct-update! (type field f xs)
|
|
"Mutably apply F to FIELD in XS."
|
|
(let ((accessor (struct--accessor-for type field)))
|
|
`(progn
|
|
(setf (,accessor ,xs) (funcall ,f (,accessor ,xs)))
|
|
,xs)))
|
|
|
|
(defmacro struct-set (type field x xs)
|
|
"Immutably set FIELD in XS (struct TYPE) to X."
|
|
(let ((copier (struct--copier-for type))
|
|
(accessor (struct--accessor-for type field)))
|
|
`(let ((copy (,copier ,xs)))
|
|
(setf (,accessor copy) ,x)
|
|
copy)))
|
|
|
|
(defmacro struct-set! (type field x xs)
|
|
"Set FIELD in XS (struct TYPE) to X mutably.
|
|
This is an adapter interface to `setf'."
|
|
(let ((accessor (struct--accessor-for type field)))
|
|
`(progn
|
|
(setf (,accessor ,xs) ,x)
|
|
,xs)))
|
|
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;; Helper Functions
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
|
|
(defun struct--copier-for (type)
|
|
(intern (format "copy-%s" (symbol-name type))))
|
|
|
|
(defun struct--accessor-for (type field)
|
|
(intern (format "%s-%s"
|
|
(symbol-name type)
|
|
(symbol-name field))))
|
|
|
|
(provide 'struct)
|
|
;;; struct.el ends here
|