aa122cbae7
This CL can be used to compare the style of nixpkgs-fmt against other formatters (nixpkgs, alejandra). Change-Id: I87c6abff6bcb546b02ead15ad0405f81e01b6d9e Reviewed-on: https://cl.tvl.fyi/c/depot/+/4397 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org> Reviewed-by: lukegb <lukegb@tvl.fyi> Reviewed-by: wpcarro <wpcarro@gmail.com> Reviewed-by: Profpatsch <mail@profpatsch.de> Reviewed-by: kanepyork <rikingcoding@gmail.com> Reviewed-by: tazjin <tazjin@tvl.su> Reviewed-by: cynthia <cynthia@tvl.fyi> Reviewed-by: edef <edef@edef.eu> Reviewed-by: eta <tvl@eta.st> Reviewed-by: grfn <grfn@gws.fyi>
52 lines
1.5 KiB
Nix
52 lines
1.5 KiB
Nix
{ depot, pkgs, lib, ... }:
|
|
|
|
{
|
|
# content of the <title> tag
|
|
title
|
|
# main part of the page, usually wrapped with <main>
|
|
, content
|
|
# optional extra html to inject into <head>
|
|
, extraHead ? null
|
|
# optional extra html to inject into <footer>
|
|
, extraFooter ? null
|
|
# URL at which static assets are located
|
|
, staticUrl ? "https://static.tvl.fyi/${depot.web.static.drvHash}"
|
|
}@args:
|
|
|
|
let
|
|
inherit (pkgs) runCommandNoCC lib;
|
|
inherit (depot.tools) cheddar;
|
|
in
|
|
|
|
runCommandNoCC "${lib.strings.sanitizeDerivationName title}-index.html"
|
|
{
|
|
headerPart = ''
|
|
<!DOCTYPE html>
|
|
<head>
|
|
<meta charset="utf-8">
|
|
<meta name="viewport" content="width=device-width, initial-scale=1">
|
|
<meta name="description" content="The Virus Lounge">
|
|
<link rel="stylesheet" type="text/css" href="${staticUrl}/tvl.css" media="all">
|
|
<link rel="icon" type="image/webp" href="${staticUrl}/favicon.webp">
|
|
<link rel="alternate" type="application/atom+xml" title="Atom Feed" href="https://tvl.fyi/feed.atom">
|
|
<title>${title}</title>
|
|
'' + lib.optionalString (args ? extraHead) extraHead + ''
|
|
</head>
|
|
<body class="light">
|
|
'';
|
|
|
|
inherit content;
|
|
|
|
footerPart = ''
|
|
<hr>
|
|
<footer>
|
|
${depot.web.tvl.footer args}
|
|
</footer>
|
|
</body>
|
|
'';
|
|
|
|
passAsFile = [ "headerPart" "content" "footerPart" ];
|
|
} ''
|
|
${cheddar}/bin/cheddar --about-filter content.md < $contentPath > rendered.html
|
|
cat $headerPartPath rendered.html $footerPartPath > $out
|
|
''
|