aa122cbae7
This CL can be used to compare the style of nixpkgs-fmt against other formatters (nixpkgs, alejandra). Change-Id: I87c6abff6bcb546b02ead15ad0405f81e01b6d9e Reviewed-on: https://cl.tvl.fyi/c/depot/+/4397 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org> Reviewed-by: lukegb <lukegb@tvl.fyi> Reviewed-by: wpcarro <wpcarro@gmail.com> Reviewed-by: Profpatsch <mail@profpatsch.de> Reviewed-by: kanepyork <rikingcoding@gmail.com> Reviewed-by: tazjin <tazjin@tvl.su> Reviewed-by: cynthia <cynthia@tvl.fyi> Reviewed-by: edef <edef@edef.eu> Reviewed-by: eta <tvl@eta.st> Reviewed-by: grfn <grfn@gws.fyi>
38 lines
1.1 KiB
Nix
38 lines
1.1 KiB
Nix
# Builder for depot-internal Emacs packages. Packages built using this
|
|
# builder are added into the Emacs packages fixpoint under
|
|
# `emacsPackages.tvlPackages`, which in turn makes it possible to use
|
|
# them with special Emacs features like native compilation.
|
|
#
|
|
# Arguments passed to the builder are the same as
|
|
# emacsPackages.trivialBuild, except:
|
|
#
|
|
# * packageRequires is not used
|
|
#
|
|
# * externalRequires takes a selection function for packages from
|
|
# emacsPackages
|
|
#
|
|
# * internalRequires takes other depot packages
|
|
{ pkgs, ... }:
|
|
|
|
buildArgs:
|
|
|
|
pkgs.callPackage
|
|
({ emacsPackages }:
|
|
|
|
let
|
|
# Select external dependencies from the emacsPackages set
|
|
externalDeps = (buildArgs.externalRequires or (_: [ ])) emacsPackages;
|
|
|
|
# Override emacsPackages for depot-internal packages
|
|
internalDeps = map (p: p.override { inherit emacsPackages; })
|
|
(buildArgs.internalRequires or [ ]);
|
|
|
|
trivialBuildArgs = builtins.removeAttrs buildArgs [
|
|
"externalRequires"
|
|
"internalRequires"
|
|
] // {
|
|
packageRequires = externalDeps ++ internalDeps;
|
|
};
|
|
in
|
|
emacsPackages.trivialBuild trivialBuildArgs)
|
|
{ }
|