71435d9546
* agenix has not been updated (https://github.com/ryantm/agenix/pull/241). * wasm-bindgen bumped to 0.2.92 in Rust WASM projects * 3p/lisp: port lispPackages from stable channel The Lisp package set we are using (`pkgs.lispPackages`) is the "old old" package set, whereas we were supposed to have been using `pkgs.lispPackages_new` (which is the "old new" package set). Either way we missed that train, and now there's a "new new" package set, but with a twist: Lisp packages in nixpkgs are now tied to their compilers, so the most generic way to access them seems to be from `pkgs.sbclPackages`. Switching to the packages from the "new new" package set doesn't work: Lots of stuff stops building if we just switch the sources over, and not everything is trivially fixable. For now we stay on the lispPackages from the stable channel. We need to look into the migration later. Or rewrite panettone. * tvix: update generated protobuf files * 3p/nixpkgs: pick trunk from stable channel; newer versions try to read files and do network I/O during build, but don't print enough details in error messages to figure out why. * 3p/overlays: remove tdlib override (nixpkgs is currently new enough) * 3p/overlays: override telega.el sources while updates are lagging in nixpkgs * users/flokli/ipu6-softisp: update firmware paths, which NixOS now stores zstd-compressed. Change-Id: I5a7a6c8b5d0688461bca92b9e6d654356d3a1cf1 Reviewed-on: https://cl.tvl.fyi/c/depot/+/11711 Tested-by: BuildkiteCI Reviewed-by: flokli <flokli@flokli.de> Reviewed-by: tazjin <tazjin@tvl.su>
82 lines
3 KiB
Nix
82 lines
3 KiB
Nix
# This file imports the pinned nixpkgs sets and applies relevant
|
|
# modifications, such as our overlays.
|
|
#
|
|
# The actual source pinning happens via niv in //third_party/sources
|
|
#
|
|
# Note that the attribute exposed by this (third_party.nixpkgs) is
|
|
# "special" in that the fixpoint used as readTree's config parameter
|
|
# in //default.nix passes this attribute as the `pkgs` argument to all
|
|
# readTree derivations.
|
|
|
|
{ depot ? { }
|
|
, externalArgs ? { }
|
|
, depotOverlays ? true
|
|
, localSystem ? externalArgs.localSystem or builtins.currentSystem
|
|
, crossSystem ? externalArgs.crossSystem or localSystem
|
|
# additional overlays to be applied.
|
|
# Useful when calling this file in a view exported from depot.
|
|
, additionalOverlays ? [ ]
|
|
, ...
|
|
}:
|
|
|
|
let
|
|
# Arguments passed to both the stable nixpkgs and the main, unstable one.
|
|
# Includes everything but overlays which are only passed to unstable nixpkgs.
|
|
commonNixpkgsArgs = {
|
|
# allow users to inject their config into builds (e.g. to test CA derivations)
|
|
config =
|
|
(if externalArgs ? nixpkgsConfig then externalArgs.nixpkgsConfig else { })
|
|
// {
|
|
allowUnfree = true;
|
|
allowUnfreeRedistributable = true;
|
|
allowBroken = true;
|
|
# Forbids our meta.ci attribute
|
|
# https://github.com/NixOS/nixpkgs/pull/191171#issuecomment-1260650771
|
|
checkMeta = false;
|
|
};
|
|
|
|
inherit localSystem crossSystem;
|
|
};
|
|
|
|
# import the nixos-unstable package set, or optionally use the
|
|
# source (e.g. a path) specified by the `nixpkgsBisectPath`
|
|
# argument. This is intended for use-cases where the depot is
|
|
# bisected against nixpkgs to find the root cause of an issue in a
|
|
# channel bump.
|
|
nixpkgsSrc = externalArgs.nixpkgsBisectPath or depot.third_party.sources.nixpkgs;
|
|
|
|
# Stable package set is imported, but not exposed, to overlay
|
|
# required packages into the unstable set.
|
|
stableNixpkgs = import depot.third_party.sources.nixpkgs-stable commonNixpkgsArgs;
|
|
|
|
# Overlay for packages that should come from the stable channel
|
|
# instead (e.g. because something is broken in unstable).
|
|
# Use `stableNixpkgs` from above.
|
|
stableOverlay = _unstableSelf: unstableSuper: {
|
|
# newer trunk fails somewhere within reqwest, trying to read a mystery file
|
|
trunk = stableNixpkgs.trunk;
|
|
|
|
# the big lis package change breaks everything in //3p/lisp, undo it for now.
|
|
lispPackages = stableNixpkgs.lispPackages;
|
|
};
|
|
|
|
# Overlay to expose the nixpkgs commits we are using to other Nix code.
|
|
commitsOverlay = _: _: {
|
|
nixpkgsCommits = {
|
|
unstable = depot.third_party.sources.nixpkgs.rev;
|
|
stable = depot.third_party.sources.nixpkgs-stable.rev;
|
|
};
|
|
};
|
|
in
|
|
import nixpkgsSrc (commonNixpkgsArgs // {
|
|
overlays = [
|
|
commitsOverlay
|
|
stableOverlay
|
|
] ++ (if depotOverlays then [
|
|
depot.third_party.overlays.haskell
|
|
depot.third_party.overlays.tvl
|
|
depot.third_party.overlays.ecl-static
|
|
depot.third_party.overlays.dhall
|
|
(import depot.third_party.sources.rust-overlay)
|
|
] else [ ] ++ additionalOverlays);
|
|
})
|