473604f567
Please read b/108 to make sense of this. This gets rid of the explicit list of exposed packages from nixpkgs, and instead makes the entire package set available at `third_party.nixpkgs`. To accommodate this, a LOT of things have to be very slightly shuffled around. Some of this was done in already submitted CLs, but this change is unfortunately still quite noisy. Pay extra attention to: * overlay-like functionality that was partially moved to actual overlays (partially as in, the minimum required to get a green build) * modified uses of the package set path, esp. in NixOS systems Special notes: * xanthous has been disabled in CI because of issues with the Haskell overlay * //third_party/nix has been disabled because of other unclear dependency issues Both of these will be tackled in a followup CL. Change-Id: I2f9c60a4d275fdb5209264be0addfd7e06c53118 Reviewed-on: https://cl.tvl.fyi/c/depot/+/2910 Reviewed-by: glittershark <grfn@gws.fyi> Reviewed-by: sterni <sternenseemann@systemli.org> Tested-by: BuildkiteCI
105 lines
3.4 KiB
Nix
105 lines
3.4 KiB
Nix
# This file sets up the top-level package set by traversing the package tree
|
|
# (see read-tree.nix for details) and constructing a matching attribute set
|
|
# tree.
|
|
#
|
|
# This makes packages accessible via the Nixery instance that is configured to
|
|
# use this repository as its nixpkgs source.
|
|
|
|
{ ... }@args:
|
|
|
|
with builtins;
|
|
|
|
let
|
|
# This definition of fix is identical to <nixpkgs>.lib.fix, but the global
|
|
# package set is not available here.
|
|
fix = f: let x = f x; in x;
|
|
|
|
# Global configuration that all packages are called with.
|
|
config = depot: {
|
|
inherit depot;
|
|
|
|
# Expose lib attribute to packages.
|
|
inherit (depot.third_party.nixpkgs) lib;
|
|
|
|
# Pass third_party as 'pkgs' (for compatibility with external
|
|
# imports for certain subdirectories)
|
|
pkgs = depot.third_party.nixpkgs;
|
|
};
|
|
|
|
readTree' = import ./nix/readTree {};
|
|
|
|
localPkgs = readTree: {
|
|
fun = readTree ./fun;
|
|
lisp = readTree ./lisp;
|
|
net = readTree ./net;
|
|
nix = readTree ./nix;
|
|
ops = readTree ./ops;
|
|
third_party = readTree ./third_party;
|
|
tools = readTree ./tools;
|
|
tvix = readTree ./tvix;
|
|
users = readTree ./users;
|
|
web = readTree ./web;
|
|
};
|
|
|
|
# To determine build targets, we walk through the depot tree and
|
|
# fetch attributes that were imported by readTree and are buildable.
|
|
#
|
|
# Any build target that contains `meta.ci = false` will be skipped.
|
|
|
|
# Is this tree node eligible for build inclusion?
|
|
eligible = node: (node ? outPath) && (node.meta.ci or true);
|
|
|
|
# Walk the tree starting with 'node', recursively extending the list
|
|
# of build targets with anything that looks buildable.
|
|
#
|
|
# Any tree node can specify logical targets by exporting a
|
|
# 'meta.targets' attribute containing a list of keys in itself. This
|
|
# enables target specifications that do not exist on disk directly.
|
|
gather = node:
|
|
if node ? __readTree then
|
|
# Include the node itself if it is eligible.
|
|
(if eligible node then [ node ] else [])
|
|
# Include eligible children of the node
|
|
++ concatMap gather (attrValues node)
|
|
# Include specified sub-targets of the node
|
|
++ filter eligible (map
|
|
(k: (node."${k}" or {}) // {
|
|
# Keep the same tree location, but explicitly mark this
|
|
# node as a subtarget.
|
|
__readTree = node.__readTree;
|
|
__subtarget = k;
|
|
})
|
|
(node.meta.targets or []))
|
|
else [];
|
|
in fix(self: {
|
|
__readTree = [];
|
|
config = config self;
|
|
|
|
# Expose readTree for downstream repo consumers.
|
|
readTree = {
|
|
__functor = x: (readTree' x.config);
|
|
config = self.config;
|
|
};
|
|
|
|
# Make the path to the depot available for things that might need it
|
|
# (e.g. NixOS module inclusions)
|
|
depotPath = ./.;
|
|
|
|
# List of all buildable targets, for CI purposes.
|
|
#
|
|
# Note: To prevent infinite recursion, this *must* be a nested
|
|
# attribute set (which does not have a __readTree attribute).
|
|
ci.targets = gather (self // {
|
|
# remove the pipelines themselves from the set over which to
|
|
# generate pipelines because that also leads to infinite
|
|
# recursion.
|
|
ops = self.ops // { pipelines = null; };
|
|
|
|
# remove nixpkgs from the set, for obvious reasons.
|
|
third_party = self.third_party // { nixpkgs = null; };
|
|
});
|
|
}
|
|
|
|
# Add local packages as structured by readTree
|
|
// (localPkgs (readTree' self.config))
|
|
)
|