508a62b603
* Remove use of aliases that have been removed in nixpkgs commit a36f455905d55838a0d284656e096fbdb857cf3a: - ncat - x11 - nologin - dbus_libs - emacsPackagesGen - man-pages - pulseaudioLight Change-Id: Ide603bf48bc7f77e10e4aa715ba025aece3644fd Reviewed-on: https://cl.tvl.fyi/c/depot/+/5387 Tested-by: BuildkiteCI Autosubmit: sterni <sternenseemann@systemli.org> Reviewed-by: tazjin <tazjin@tvl.su> Reviewed-by: grfn <grfn@gws.fyi> Reviewed-by: wpcarro <wpcarro@gmail.com>
68 lines
1.5 KiB
Nix
68 lines
1.5 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with pkgs;
|
|
|
|
let
|
|
libuiohook = stdenv.mkDerivation rec {
|
|
pname = "libuiohook";
|
|
version = "1.1";
|
|
src = fetchFromGitHub {
|
|
owner = "kwhat";
|
|
repo = "libuiohook";
|
|
rev = version;
|
|
sha256 = "1isfxn3cfrdqq22d3mlz2lzm4asf9gprs7ww2xy9c3j3srk9kd7r";
|
|
};
|
|
|
|
preConfigure = ''
|
|
./bootstrap.sh
|
|
'';
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
buildInputs = [
|
|
libtool
|
|
autoconf
|
|
automake
|
|
xlibsWrapper
|
|
xorg.libXtst
|
|
xorg.libXinerama
|
|
xorg.libxkbfile
|
|
libxkbcommon
|
|
];
|
|
};
|
|
|
|
obs-input-overlay = stdenv.mkDerivation rec {
|
|
pname = "obs-input-overlay";
|
|
version = "4.8";
|
|
src = fetchFromGitHub {
|
|
owner = "univrsal";
|
|
repo = "input-overlay";
|
|
rev = "v${version}";
|
|
sha256 = "1dklg0dx9ijwyhgwcaqz859rbpaivmqxqvh9w3h4byrh5pnkz8bf";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
nativeBuildInputs = [ cmake ];
|
|
buildInputs = [ obs-studio libuiohook ];
|
|
|
|
postPatch = ''
|
|
sed -i CMakeLists.txt \
|
|
-e '2iinclude(${obs-studio.src}/cmake/Modules/ObsHelpers.cmake)' \
|
|
-e '2ifind_package(LibObs REQUIRED)'
|
|
'';
|
|
|
|
cmakeFlags = [
|
|
"-Wno-dev"
|
|
];
|
|
};
|
|
in
|
|
{
|
|
home.packages = [
|
|
obs-studio
|
|
obs-input-overlay
|
|
];
|
|
|
|
xdg.configFile."obs-studio/plugins/input-overlay/bin/64bit/input-overlay.so".source =
|
|
"${obs-input-overlay}/lib/obs-plugins/input-overlay.so";
|
|
xdg.configFile."obs-studio/plugins/input-overlay/data".source =
|
|
"${obs-input-overlay}/share/obs/obs-plugins/input-overlay";
|
|
}
|