425637b63b
... bumping these in the same commit to avoid double-recompilation of Emacs stuff. Change-Id: Ieab114115b788c36e9d42246445cf17b960c11de Reviewed-on: https://cl.tvl.fyi/c/depot/+/3741 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org>
71 lines
2.4 KiB
Nix
71 lines
2.4 KiB
Nix
# This file imports the pinned nixpkgs sets and applies relevant
|
|
# modifications, such as our overlays.
|
|
#
|
|
# Note that the attribute exposed by this (third_party.nixpkgs) is
|
|
# "special" in that the fixpoint used as readTree's config parameter
|
|
# in //default.nix passes this attribute as the `pkgs` argument to all
|
|
# readTree derivations.
|
|
|
|
{ depot, externalArgs, ... }:
|
|
|
|
let
|
|
# This provides the sources of nixpkgs. We track both
|
|
# nixos-unstable, and the current stable channel of the latest NixOS
|
|
# release.
|
|
|
|
# Tracking nixos-unstable as of 2021-10-19.
|
|
unstableHashes = {
|
|
commit = "5f0194220f2402b06f7f79bba6351895facb5acb";
|
|
sha256 = "0h2j0ivbp3b84d38h8s06s2yvnwqy80f4i1a75jd11m45m804n3s";
|
|
};
|
|
|
|
# Tracking nixos-21.05 as of 2021-10-21.
|
|
stableHashes = {
|
|
commit = "70904d4a9927a4d6e05c72c4aaac4370e05107f3";
|
|
sha256 = "08vvir0npyrdx85ypiannwzvyryqdw3749bghffhdsq2dgz1cx8z";
|
|
};
|
|
|
|
# import the nixos-unstable package set, or optionally use the
|
|
# source (e.g. a path) specified by the `nixpkgsBisectPath`
|
|
# argument. This is intended for use-cases where the depot is
|
|
# bisected against nixpkgs to find the root cause of an issue in a
|
|
# channel bump.
|
|
nixpkgsSrc = externalArgs.nixpkgsBisectPath or (fetchTarball {
|
|
url = "https://github.com/NixOS/nixpkgs/archive/${unstableHashes.commit}.tar.gz";
|
|
sha256 = unstableHashes.sha256;
|
|
});
|
|
|
|
stableNixpkgsSrc = fetchTarball {
|
|
url = "https://github.com/NixOS/nixpkgs/archive/${stableHashes.commit}.tar.gz";
|
|
sha256 = stableHashes.sha256;
|
|
};
|
|
|
|
# Stable package set is imported, but not exposed, to overlay
|
|
# required packages into the unstable set.
|
|
stableNixpkgs = import stableNixpkgsSrc {};
|
|
|
|
# Overlay for packages that should come from the stable channel
|
|
# instead (e.g. because something is broken in unstable).
|
|
stableOverlay = self: super: {
|
|
# Nothing picked from stable presently.
|
|
};
|
|
|
|
# Overlay to expose the nixpkgs commits we are using to other Nix code.
|
|
commitsOverlay = _: _: {
|
|
nixpkgsCommits = {
|
|
unstable = unstableHashes.commit;
|
|
stable = stableHashes.commit;
|
|
};
|
|
};
|
|
in import nixpkgsSrc {
|
|
config.allowUnfree = true;
|
|
config.allowBroken = true;
|
|
overlays = [
|
|
commitsOverlay
|
|
stableOverlay
|
|
depot.third_party.overlays.haskell
|
|
depot.third_party.overlays.emacs
|
|
depot.third_party.overlays.tvl
|
|
depot.third_party.overlays.ecl-static
|
|
];
|
|
}
|