9019d8568e
vhost-user-backend doesn't support macOS yet, so the virtiofs features will not work on macOS. This removes it as a default feature which makes `cargo build` work out of the box on macOS. The `virtiofs` feature is enabled for Linux when building via Nix, but if being built by cargo directly, the feature must be enabled via a cargo flag. Change-Id: I2aaca9582f8e3dbcf9ee5f1b9831d614909f3799 Reviewed-on: https://cl.tvl.fyi/c/depot/+/9555 Reviewed-by: flokli <flokli@flokli.de> Tested-by: BuildkiteCI Autosubmit: Connor Brewster <cbrewster@hey.com>
34 lines
1.1 KiB
Nix
34 lines
1.1 KiB
Nix
{ depot, pkgs, ... }:
|
|
|
|
let
|
|
mkImportCheck = p: expectedPath: {
|
|
label = ":nix :import ${p} with tvix-store import";
|
|
needsOutput = true;
|
|
command = pkgs.writeShellScript "tvix-import-check" ''
|
|
export BLOB_SERVICE_ADDR=memory://
|
|
export DIRECTORY_SERVICE_ADDR=memory://
|
|
export PATH_INFO_SERVICE_ADDR=memory://
|
|
TVIX_STORE_OUTPUT=$(result/bin/tvix-store import ${p})
|
|
EXPECTED='${/* the vebatim expected Tvix output: */expectedPath}'
|
|
|
|
echo "tvix-store output: ''${TVIX_STORE_OUTPUT}"
|
|
if [ "$TVIX_STORE_OUTPUT" != "$EXPECTED" ]; then
|
|
echo "Correct would have been ''${EXPECTED}"
|
|
exit 1
|
|
fi
|
|
|
|
echo "Output was correct."
|
|
'';
|
|
};
|
|
in
|
|
|
|
(depot.tvix.crates.workspaceMembers.tvix-store.build.override {
|
|
runTests = true;
|
|
# virtiofs feature currently fails to build on Darwin.
|
|
# we however can ship it for non-darwin.
|
|
features = if pkgs.stdenv.isDarwin then [ "default" ] else [ "default" "virtiofs" ];
|
|
}).overrideAttrs (_: {
|
|
meta.ci.extraSteps = {
|
|
import-docs = (mkImportCheck "tvix/store/docs" ./docs);
|
|
};
|
|
})
|