afe4dfb61e
Also expose both formats, then use it from users/tazjin/presentations/tvix-eval-2023. Change-Id: Id906e8aff5510a7a4f33336326472e86db18ea32 Reviewed-on: https://cl.tvl.fyi/c/depot/+/9280 Tested-by: BuildkiteCI Autosubmit: flokli <flokli@flokli.de> Reviewed-by: tazjin <tazjin@tvl.su>
63 lines
1.4 KiB
Nix
63 lines
1.4 KiB
Nix
{ depot, pkgs, ... }:
|
|
|
|
let
|
|
inherit (pkgs) fontconfig texlive stdenv imagemagick runCommand qrencode;
|
|
|
|
tex = texlive.combine {
|
|
inherit (texlive)
|
|
babel
|
|
babel-russian
|
|
beamer
|
|
beamertheme-metropolis
|
|
etoolbox
|
|
euenc
|
|
extsizes
|
|
fontspec
|
|
listings
|
|
xetex
|
|
minted
|
|
ms
|
|
pgfopts
|
|
scheme-basic
|
|
translator;
|
|
};
|
|
|
|
linksQrCode = runCommand "qrcode.png" { } ''
|
|
${qrencode}/bin/qrencode -o code.png -s 8 \
|
|
--background=fafafa \
|
|
--foreground=000000 \
|
|
'https://tazj.in/blog/tvix-eval-talk-2023'
|
|
|
|
# latex has trouble with the PDF produced by qrencode
|
|
${imagemagick}/bin/convert code.png $out
|
|
'';
|
|
in
|
|
stdenv.mkDerivation {
|
|
name = "progmsk-tvix-eval";
|
|
src = ./.;
|
|
|
|
nativeBuildInputs = [ tex imagemagick fontconfig ];
|
|
|
|
FONTCONFIG_FILE = pkgs.makeFontsConf {
|
|
fontDirectories = with pkgs; [ jetbrains-mono fira fira-code fira-mono ];
|
|
};
|
|
|
|
buildPhase = ''
|
|
# LaTeX needs a cache folder in /home/ ...
|
|
mkdir home
|
|
export HOME=$PWD/home
|
|
|
|
cp ${depot.tvix.logo}/logo.png tvix-logo.png
|
|
cp ${linksQrCode} qrcode.png
|
|
|
|
# As usual, TeX needs to be run twice ...
|
|
${tex}/bin/xelatex presentation.tex
|
|
${tex}/bin/xelatex presentation.tex
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out
|
|
cp presentation.pdf $out/
|
|
cp $src/presentation.pdfpc $out/
|
|
'';
|
|
}
|