1e3306ab57
bash (unlike fish) doesn't break down if TERM=dumb which is the only one I'll be using in emacs (I want to reduce my usage of things depending on ANSI escape sequence to a minimum, for stuff that needs it I still have foot). bash is started in login shell mode so /etc/profile is sourced which will a) enable direnv support and b) setup some tweaks (relating to PAGER etc.) if TERM=dumb. Since I use a semicolon for a prompt in (ba)sh, shell-prompt-pattern needs to be adjusted. Change-Id: If58b6d1edf1d9ab1883cb51c27729e23d889b16c Reviewed-on: https://cl.tvl.fyi/c/depot/+/5570 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org> Autosubmit: sterni <sternenseemann@systemli.org>
85 lines
2.6 KiB
Nix
85 lines
2.6 KiB
Nix
{ depot, pkgs, ... }:
|
|
|
|
let
|
|
inherit (pkgs.emacsNativeComp.pkgs) withPackages;
|
|
|
|
emacs = withPackages (epkgs: [
|
|
epkgs.bqn-mode
|
|
epkgs.elpaPackages.ada-mode
|
|
epkgs.elpaPackages.rainbow-mode
|
|
epkgs.elpaPackages.undo-tree
|
|
epkgs.melpaPackages.adoc-mode
|
|
epkgs.melpaPackages.cmake-mode
|
|
epkgs.melpaPackages.direnv
|
|
epkgs.melpaPackages.dockerfile-mode
|
|
epkgs.melpaPackages.elfeed
|
|
epkgs.melpaPackages.evil
|
|
epkgs.melpaPackages.evil-collection
|
|
epkgs.melpaPackages.haskell-mode
|
|
epkgs.melpaPackages.hl-todo
|
|
epkgs.melpaPackages.jq-mode
|
|
epkgs.melpaPackages.languagetool
|
|
epkgs.melpaPackages.lsp-haskell
|
|
epkgs.melpaPackages.lsp-mode
|
|
epkgs.melpaPackages.magit
|
|
epkgs.melpaPackages.markdown-mode
|
|
epkgs.melpaPackages.meson-mode
|
|
epkgs.melpaPackages.nix-mode
|
|
epkgs.melpaPackages.paredit
|
|
epkgs.melpaPackages.rainbow-delimiters
|
|
epkgs.melpaPackages.sly
|
|
epkgs.melpaPackages.use-package
|
|
epkgs.melpaPackages.yaml-mode
|
|
epkgs.rust-mode
|
|
epkgs.tvlPackages.tvl
|
|
epkgs.urweb-mode
|
|
]);
|
|
|
|
configDirectory = pkgs.symlinkJoin {
|
|
name = "emacs.d";
|
|
paths = [
|
|
./.
|
|
(pkgs.writeTextFile {
|
|
name = "injected-emacs.d";
|
|
destination = "/nix-inject.el";
|
|
text = ''
|
|
;; bqn-mode
|
|
(setq bqn-interpreter-path "${pkgs.cbqn}/bin/BQN")
|
|
|
|
;; languagetool
|
|
(setq languagetool-java-bin "${pkgs.jre}/bin/java"
|
|
languagetool-console-command "${pkgs.languagetool}/share/languagetool-commandline.jar"
|
|
languagetool-server-command "${pkgs.languagetool}/share/languagetool-server.jar"
|
|
languagetool-java-arguments '("-Dfile.encoding=UTF-8"))
|
|
|
|
;; use bash instead of fish from SHELL for some things, as it plays
|
|
;; nicer with TERM=dumb, as I don't need/want vterm anyways.
|
|
;; We want it to source /etc/profile for some extra setup that
|
|
;; kicks in if TERM=dumb, meaning we can't use dash/sh mode.
|
|
(setq shell-file-name "${pkgs.bash}/bin/bash"
|
|
explicit-bash-args '("-l"))
|
|
|
|
(provide 'nix-inject)
|
|
'';
|
|
})
|
|
];
|
|
postBuild = ''
|
|
rm "$out/default.nix"
|
|
'';
|
|
};
|
|
in
|
|
|
|
# sadly we can't give an init-file via the command line
|
|
(pkgs.writeShellScriptBin "emacs" ''
|
|
exec ${emacs}/bin/emacs \
|
|
--no-init-file \
|
|
--directory ${configDirectory} \
|
|
--eval "(require 'init)" \
|
|
"$@"
|
|
'').overrideAttrs (super: {
|
|
buildCommand = ''
|
|
${super.buildCommand}
|
|
|
|
ln -s "${emacs}/bin/emacsclient" "$out/bin/emacsclient"
|
|
'';
|
|
})
|