4450003bd7
Fixes a long-standing todo by adding an additional field for the time at which a post was updated, and handling this in both site generation (to note the update date after the publish date) and in Atom feed generation (by populating both the updated and published fields). Change-Id: If80db43459b2a0c77eea4dde7255651b5d6cd64b Reviewed-on: https://cl.tvl.fyi/c/depot/+/2766 Reviewed-by: tazjin <mail@tazj.in> Tested-by: BuildkiteCI
61 lines
1.7 KiB
Nix
61 lines
1.7 KiB
Nix
# This creates the static files that make up my blog from the Markdown
|
|
# files in this repository.
|
|
#
|
|
# All blog posts are rendered from Markdown by cheddar.
|
|
{ depot, lib, ... }@args:
|
|
|
|
with depot.nix.yants;
|
|
|
|
let
|
|
inherit (builtins) filter hasAttr map;
|
|
|
|
# Type definition for a single blog post.
|
|
post = struct "blog-post" {
|
|
key = string; #
|
|
title = string;
|
|
date = int;
|
|
|
|
# Optional time at which this post was last updated.
|
|
updated = option int;
|
|
|
|
# Path to the Markdown file containing the post content.
|
|
content = path;
|
|
|
|
# Should this post be included in the index? (defaults to true)
|
|
listed = option bool;
|
|
|
|
# Is this a draft? (adds a banner indicating that the link should
|
|
# not be shared)
|
|
draft = option bool;
|
|
|
|
# Previously each post title had a numeric ID. For these numeric
|
|
# IDs, redirects are generated so that old URLs stay compatible.
|
|
oldKey = option string;
|
|
};
|
|
|
|
posts = list post (import ./posts.nix);
|
|
fragments = import ./fragments.nix args;
|
|
|
|
rendered = depot.third_party.runCommandNoCC "tazjins-blog" {} ''
|
|
mkdir -p $out
|
|
|
|
${lib.concatStringsSep "\n" (map (post:
|
|
"cp ${fragments.renderPost post} $out/${post.key}.html"
|
|
) posts)}
|
|
'';
|
|
|
|
includePost = post: !(fragments.isDraft post) && !(fragments.isUnlisted post);
|
|
in {
|
|
inherit post rendered;
|
|
static = ./static;
|
|
|
|
# Only include listed posts
|
|
posts = filter includePost posts;
|
|
|
|
# Generate embeddable nginx configuration for redirects from old post URLs
|
|
oldRedirects = lib.concatStringsSep "\n" (map (post: ''
|
|
location ~* ^(/en)?/${post.oldKey} {
|
|
return 301 https://tazj.in/blog/${post.key};
|
|
}
|
|
'') (filter (hasAttr "oldKey") posts));
|
|
}
|