16db185d97
* //third_party/overlays/tvl: remove SBCL override, as SBCL 2.2.11 fixes the bug we were running into. * //fun/gemma: use historical nixpkgs for everything due to ABI incompatibilities triggered by preloaded libredirect.so wanting GLIBC_2.34 which is not available in elm-make. Change-Id: I465f0366413856e45ddd1e67fc9d732075e2f3c5 Reviewed-on: https://cl.tvl.fyi/c/depot/+/7595 Tested-by: BuildkiteCI Autosubmit: sterni <sternenseemann@systemli.org> Reviewed-by: grfn <grfn@gws.fyi>
123 lines
3.5 KiB
Nix
123 lines
3.5 KiB
Nix
# This overlay is used to make TVL-specific modifications in the
|
|
# nixpkgs tree, where required.
|
|
{ depot, localSystem, ... }:
|
|
|
|
self: super:
|
|
let
|
|
# Rollback Nix to a stable version (2.3) with backports for
|
|
# build-user problems applied.
|
|
nixSrc =
|
|
let
|
|
# branch 2.3-backport-await-users
|
|
rev = "46a91f2abaee85135cbb447c13957d3c5e9091a9";
|
|
in
|
|
self.fetchFromGitHub
|
|
{
|
|
owner = "tvlfyi";
|
|
repo = "nix";
|
|
inherit rev;
|
|
hash = "sha256:0rwyrh471c5y64axyd8vzzzmzlscg97fsrjbgbm1a93wnzxcvnvk";
|
|
} // { revCount = 0; shortRev = builtins.substring 0 7 rev; };
|
|
|
|
nixTarball = (scopedImport
|
|
{
|
|
# The tarball job always uses currentSystem which we need to purify
|
|
builtins = builtins // { currentSystem = localSystem; };
|
|
}
|
|
"${nixSrc}/release.nix"
|
|
{
|
|
nix = nixSrc;
|
|
nixpkgs = self.path;
|
|
systems = [ ];
|
|
}
|
|
).tarball;
|
|
in
|
|
{
|
|
nix_2_3 = super.nix_2_3.overrideAttrs (_: {
|
|
src = "${nixTarball}/tarballs/nix-${nixTarball.version}.tar.xz";
|
|
});
|
|
nix = self.nix_2_3;
|
|
nix_latest = super.nix;
|
|
|
|
nvd = super.nvd.overrideAttrs (old: {
|
|
patches = old.patches or [ ] ++ [
|
|
./patches/nvd-nix-2.3.patch
|
|
];
|
|
});
|
|
|
|
home-manager = super.home-manager.overrideAttrs (_: {
|
|
src = depot.third_party.sources.home-manager;
|
|
version = "git-"
|
|
+ builtins.substring 0 7 depot.third_party.sources.home-manager.rev;
|
|
});
|
|
|
|
clang-tools_11 = self.clang-tools.override {
|
|
llvmPackages = self.llvmPackages_11;
|
|
};
|
|
|
|
# stdenv which uses clang, lld and libc++; full is a slight exaggeration,
|
|
# we for example don't use LLVM's libunwind
|
|
fullLlvm11Stdenv = self.overrideCC self.stdenv
|
|
(self.llvmPackages_11.libcxxStdenv.cc.override {
|
|
inherit (self.llvmPackages_11) bintools;
|
|
});
|
|
|
|
# Add our Emacs packages to the fixpoint
|
|
emacsPackagesFor = emacs: (
|
|
(super.emacsPackagesFor emacs).overrideScope' (eself: esuper: {
|
|
tvlPackages = depot.tools.emacs-pkgs // depot.third_party.emacs;
|
|
|
|
# Use the notmuch from nixpkgs instead of from the Emacs
|
|
# overlay, to avoid versions being out of sync.
|
|
notmuch = super.notmuch.emacs;
|
|
|
|
# Build EXWM with the depot sources instead.
|
|
exwm = esuper.exwm.overrideAttrs (_: {
|
|
src = depot.path.origSrc + "/third_party/exwm";
|
|
});
|
|
|
|
# Workaround for magit checking the git version at load time
|
|
magit = esuper.magit.overrideAttrs (_: {
|
|
propagatedNativeBuildInputs = [
|
|
self.git
|
|
];
|
|
});
|
|
})
|
|
);
|
|
|
|
# dottime support for notmuch
|
|
notmuch = super.notmuch.overrideAttrs (old: {
|
|
passthru = old.passthru // {
|
|
patches = old.patches ++ [ ./patches/notmuch-dottime.patch ];
|
|
};
|
|
});
|
|
|
|
# nix-serve does not work with nix 2.4
|
|
# https://github.com/edolstra/nix-serve/issues/28
|
|
nix-serve = super.nix-serve.override { nix = super.nix_2_3; };
|
|
|
|
# Avoid builds of mkShell derivations in CI.
|
|
mkShell = super.lib.makeOverridable (args: (super.mkShell args).overrideAttrs (_: {
|
|
passthru = {
|
|
meta.ci.skip = true;
|
|
};
|
|
}));
|
|
|
|
# Pin a newer version of crate2nix from git, which is not officially
|
|
# released but supports `dep:`
|
|
crate2nix = super.crate2nix.overrideAttrs (old: rec {
|
|
version = "0.11.0-rc.1";
|
|
|
|
src = self.fetchFromGitHub {
|
|
owner = "kolloch";
|
|
repo = "crate2nix";
|
|
rev = "v0.11.0-rc.1";
|
|
hash = "sha256:02yvn61w16sgkdxa019l5y9i2ybyk8h4516718gmarqxx5ws2kz8";
|
|
};
|
|
|
|
cargoDeps = old.cargoDeps.overrideAttrs (_: {
|
|
inherit src;
|
|
outputHash = "sha256:03yny9ikqzfpi2mr27r82g54an2s8k9lqi2i4fqalg7g0s2cr2yd";
|
|
});
|
|
});
|
|
}
|