bef796d1d9
Change-Id: I4208cf9e3c5e1d922ee5b5bffd034e4ac6d0e2c0 Reviewed-on: https://cl.tvl.fyi/c/depot/+/3543 Tested-by: BuildkiteCI Reviewed-by: tazjin <mail@tazj.in>
79 lines
2.5 KiB
Nix
79 lines
2.5 KiB
Nix
{ depot, lib, ... }:
|
|
|
|
let
|
|
inherit (depot.nix.runTestsuite)
|
|
runTestsuite
|
|
it
|
|
assertEq
|
|
assertThrows
|
|
assertDoesNotThrow
|
|
;
|
|
|
|
inherit (depot.nix.utils)
|
|
isDirectory
|
|
isRegularFile
|
|
isSymlink
|
|
storePathName
|
|
;
|
|
|
|
assertUtilsPred = msg: act: exp: [
|
|
(assertDoesNotThrow "${msg} does not throw" act)
|
|
(assertEq msg (builtins.tryEval act).value exp)
|
|
];
|
|
|
|
pathPredicates = it "judges paths correctly" (lib.flatten [
|
|
# isDirectory
|
|
(assertUtilsPred "directory isDirectory"
|
|
(isDirectory ./directory) true)
|
|
(assertUtilsPred "symlink not isDirectory"
|
|
(isDirectory ./symlink-directory) false)
|
|
(assertUtilsPred "file not isDirectory"
|
|
(isDirectory ./directory/file) false)
|
|
# isRegularFile
|
|
(assertUtilsPred "file isRegularFile"
|
|
(isRegularFile ./directory/file) true)
|
|
(assertUtilsPred "symlink not isRegularFile"
|
|
(isRegularFile ./symlink-file) false)
|
|
(assertUtilsPred "directory not isRegularFile"
|
|
(isRegularFile ./directory) false)
|
|
# isSymlink
|
|
(assertUtilsPred "symlink to file isSymlink"
|
|
(isSymlink ./symlink-file) true)
|
|
(assertUtilsPred "symlink to directory isSymlink"
|
|
(isSymlink ./symlink-directory) true)
|
|
(assertUtilsPred "symlink to symlink isSymlink"
|
|
(isSymlink ./symlink-symlink-file) true)
|
|
(assertUtilsPred "symlink to missing file isSymlink"
|
|
(isSymlink ./missing) true)
|
|
(assertUtilsPred "directory not isSymlink"
|
|
(isSymlink ./directory) false)
|
|
(assertUtilsPred "file not isSymlink"
|
|
(isSymlink ./directory/file) false)
|
|
# missing files throw
|
|
(assertThrows "isDirectory throws on missing file"
|
|
(isDirectory ./does-not-exist))
|
|
(assertThrows "isRegularFile throws on missing file"
|
|
(isRegularFile ./does-not-exist))
|
|
(assertThrows "isSymlink throws on missing file"
|
|
(isSymlink ./does-not-exist))
|
|
]);
|
|
|
|
cheddarStorePath =
|
|
builtins.unsafeDiscardStringContext depot.tools.cheddar.outPath;
|
|
|
|
storePathNameTests = it "correctly gets the basename of a store path" [
|
|
(assertEq "base name of a derivation"
|
|
(storePathName depot.tools.cheddar) depot.tools.cheddar.name)
|
|
(assertEq "base name of a store path string"
|
|
(storePathName cheddarStorePath) depot.tools.cheddar.name)
|
|
(assertEq "base name of a path within a store path"
|
|
(storePathName "${cheddarStorePath}/bin/cheddar") "cheddar")
|
|
(assertEq "base name of a path"
|
|
(storePathName ../default.nix) "default.nix")
|
|
];
|
|
in
|
|
|
|
runTestsuite "nix.utils" [
|
|
pathPredicates
|
|
storePathNameTests
|
|
]
|