d81f31107d
Today when I opened my laptop, I wasn't sure if it was powered off or on because the display was blank. Thankfully the volume was muted and the LED indicator was on, which informed me that the laptop was powered on. This saved me from unnecessarily rebooting. What happened was that last night I was working from home and using my external monitor. Usually I enable my external display and disable my laptop display. But when I left for work this morning, I unplugged the HDMI cable from my laptop without disabling the external display or enabling the laptop display. I noticed a XF86 button on my laptop entitled XF86Display. I figured that this could be a nice place to bind a key to toggle my laptop display on or off. At the last minute, I had the idea to just cycle through all possible display configurations that I use; there are only three anyways. When dealing with more than two states, I realized I should use a cycle to model the configuration states. Now I'm thinking that I should be using cycles to model toggles as well - instead of just using a top-level variable that I `setq` over. I haven't refactored existing toggles to be cycles, but I am excited about this new keybinding. This commit additionally: - Moves keybindings out of display.el and into keybindings.el - Conditionally sets KBDs if using work laptop
92 lines
3.3 KiB
EmacsLisp
92 lines
3.3 KiB
EmacsLisp
;;; display.el --- Working with single or multiple displays -*- lexical-binding: t -*-
|
|
;; Author: William Carroll <wpcarro@gmail.com>
|
|
|
|
;;; Commentary:
|
|
;; Mostly wrappers around xrandr.
|
|
;;
|
|
;; TODO: Look into autorandr to see if it could be useful.
|
|
;;
|
|
;; Troubleshooting:
|
|
;; The following commands help me when I (infrequently) interact with xrandr.
|
|
;; - xrandr --listmonitors
|
|
;; - xrandr --query
|
|
|
|
;;; Code:
|
|
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;; Dependencies
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
|
|
(require 'prelude)
|
|
(require 'cycle)
|
|
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;; Constants
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
|
|
;; TODO: Consider if this logic should be conditioned by `device/work-laptop?'.
|
|
(defconst display/laptop-monitor "eDP1"
|
|
"The xrandr identifier for my primary screen (on work laptop).")
|
|
|
|
;; TODO: Why is HDMI-1, eDP-1 sometimes and HDMI1, eDP1 other times.
|
|
(defconst display/4k-monitor "HDMI1"
|
|
"The xrandr identifer for my 4K monitor.")
|
|
|
|
(defconst display/display-states (cycle/from-list '((t . t) (t . nil) (nil . t)))
|
|
"A list of cons cells modelling enabled and disabled states for my displays.
|
|
The car models the enabled state of my laptop display; the cdr models the
|
|
enabled state of my external monitor.")
|
|
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;; Library
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
|
|
;; TODO: Debug why something this scales to 4k appropriately and other times it
|
|
;; doesn't.
|
|
(defun display/enable-4k ()
|
|
"Attempt to connect to my 4K monitor."
|
|
(interactive)
|
|
(prelude/start-process
|
|
:name "display/enable-4k"
|
|
:command (string/format
|
|
"xrandr --output %s --above %s --primary --auto --size 3840x2160 --rate 30.00 --dpi 144"
|
|
display/4k-monitor
|
|
display/laptop-monitor)))
|
|
|
|
(defun display/disable-4k ()
|
|
"Disconnect from the 4K monitor."
|
|
(interactive)
|
|
(prelude/start-process
|
|
:name "display/disable-4k"
|
|
:command (string/format "xrandr --output %s --off"
|
|
display/4k-monitor)))
|
|
|
|
(defun display/enable-laptop ()
|
|
"Turn the laptop monitor off.
|
|
Sometimes this is useful when I'm sharing my screen in a Google Hangout and I
|
|
only want to present one of my monitors."
|
|
(interactive)
|
|
(prelude/start-process
|
|
:name "display/disable-laptop"
|
|
:command (string/format "xrandr --output %s --auto"
|
|
display/laptop-monitor)))
|
|
|
|
(defun display/disable-laptop ()
|
|
"Turn the laptop monitor off.
|
|
Sometimes this is useful when I'm sharing my screen in a Google Hangout and I
|
|
only want to present one of my monitors."
|
|
(interactive)
|
|
(prelude/start-process
|
|
:name "display/disable-laptop"
|
|
:command (string/format "xrandr --output %s --off"
|
|
display/laptop-monitor)))
|
|
|
|
(defun display/cycle-display-states ()
|
|
"Cycle through `display/display-states' enabling and disabling displays."
|
|
(interactive)
|
|
(let ((state (cycle/next display/display-states)))
|
|
(if (car state) (display/enable-laptop) (display/disable-laptop))
|
|
(if (cdr state) (display/enable-4k) (display/disable-4k))))
|
|
|
|
(provide 'display)
|
|
;;; display.el ends here
|