001ee91169
This way ci should pick up on clhs-lookup since only a single derivation is exposed with the default.nix and it is less cumbersome to type the attribute path (users.sterni.clhs.clhs-lookup → users.sterni.clhs-lookup). The exposed CLHS wasn't used for anything anyways and I can always expose it again using passthru or extra if it's ever merged. Change-Id: I6c5aeba1b58ca650700c6efa0913e4b42685ea6b Reviewed-on: https://cl.tvl.fyi/c/depot/+/2461 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org>
36 lines
811 B
Nix
36 lines
811 B
Nix
{ pkgs, depot, ... }:
|
|
|
|
let
|
|
inherit (pkgs) fetchzip writeText;
|
|
inherit (depot.nix) buildLisp;
|
|
inherit (builtins) replaceStrings;
|
|
|
|
clhsVersion = "7-0";
|
|
|
|
clhs = fetchzip {
|
|
name = "HyperSpec-${replaceStrings [ "-" ] [ "." ] clhsVersion}";
|
|
url = "ftp://ftp.lispworks.com/pub/software_tools/reference/HyperSpec-${clhsVersion}.tar.gz";
|
|
sha256 = "1zsi35245m5sfb862ibzy0pzlph48wvlggnqanymhgqkpa1v20ak";
|
|
stripRoot = false;
|
|
};
|
|
|
|
clhs-path = writeText "clhs-path.lisp" ''
|
|
(in-package :clhs-lookup.clhs-path)
|
|
(defparameter *clhs-path* (pathname "${clhs}/"))
|
|
'';
|
|
|
|
clhs-lookup = buildLisp.program {
|
|
name = "clhs-lookup";
|
|
|
|
deps = [
|
|
(buildLisp.bundled "uiop")
|
|
];
|
|
|
|
srcs = [
|
|
./packages.lisp
|
|
clhs-path
|
|
./clhs-lookup.lisp
|
|
];
|
|
};
|
|
in
|
|
clhs-lookup
|