766677748d
See https://github.com/NixOS/nixpkgs/issues/137279 Change-Id: Id47f87396ad5e46c98080c7910d337d2643bcbd5 Reviewed-on: https://cl.tvl.fyi/c/depot/+/3604 Tested-by: BuildkiteCI Reviewed-by: tazjin <mail@tazj.in>
55 lines
1.6 KiB
Nix
55 lines
1.6 KiB
Nix
# This overlay is used to make TVL-specific modifications in the
|
|
# nixpkgs tree, where required.
|
|
{ depot, ... }:
|
|
|
|
self: super: {
|
|
# Required for apereo-cas
|
|
# TODO(lukegb): Document why?
|
|
gradle_6 = (super.gradleGen.override {
|
|
java = self.jdk11;
|
|
jdk = self.jdk11;
|
|
}).gradleGen rec {
|
|
name = "gradle-6.5.1";
|
|
nativeVersion = "0.22-milestone-3";
|
|
|
|
src = builtins.fetchurl {
|
|
url = "https://services.gradle.org/distributions/${name}-bin.zip";
|
|
sha256 = "0jmmipjh4fbsn92zpifa5cqg5ws2a4ha0s4jzqhrg4zs542x79sh";
|
|
};
|
|
};
|
|
|
|
clang-tools_11 = self.clang-tools.override {
|
|
llvmPackages = self.llvmPackages_11;
|
|
};
|
|
|
|
# Add our Emacs packages to the fixpoint
|
|
emacsPackagesFor = emacs: (
|
|
(super.emacsPackagesFor emacs).overrideScope' (eself: esuper: {
|
|
tvlPackages = depot.tools.emacs-pkgs // depot.third_party.emacs;
|
|
|
|
# Use the notmuch from nixpkgs instead of from the Emacs
|
|
# overlay, to avoid versions being out of sync.
|
|
notmuch = super.notmuch.emacs;
|
|
|
|
# Build EXWM with the depot sources instead.
|
|
exwm = esuper.exwm.overrideAttrs(_: {
|
|
src = "${depot.path + "/third_party/exwm"}";
|
|
});
|
|
})
|
|
);
|
|
|
|
# dottime support for notmuch
|
|
notmuch = super.notmuch.overrideAttrs(old: {
|
|
passthru = old.passthru // {
|
|
patches = old.patches ++ [ ./patches/notmuch-dottime.patch ];
|
|
};
|
|
});
|
|
|
|
# Use latest SBCL, nixpkgs hasn't upgraded yet
|
|
sbcl = self.sbcl_2_1_8;
|
|
|
|
# Fix Steam issues with web views (nixpkgs#137279)
|
|
steam = super.steam.override {
|
|
extraPkgs = pkgs: with pkgs; [ pango harfbuzz libthai ];
|
|
};
|
|
}
|