48d5724dab
I tried to remove the awscli2 override, the build no longer fails but just hangs infinitely on unstable now, so it's staying in for the time being. Change-Id: I871b0f5bffe0edf4db815ca4df2c3f142bc9e13d Reviewed-on: https://cl.tvl.fyi/c/depot/+/3630 Tested-by: BuildkiteCI Reviewed-by: sterni <sternenseemann@systemli.org>
72 lines
2.4 KiB
Nix
72 lines
2.4 KiB
Nix
# This file imports the pinned nixpkgs sets and applies relevant
|
|
# modifications, such as our overlays.
|
|
#
|
|
# Note that the attribute exposed by this (third_party.nixpkgs) is
|
|
# "special" in that the fixpoint used as readTree's config parameter
|
|
# in //default.nix passes this attribute as the `pkgs` argument to all
|
|
# readTree derivations.
|
|
|
|
{ depot, externalArgs, ... }:
|
|
|
|
let
|
|
# This provides the sources of nixpkgs. We track both
|
|
# nixos-unstable, and the current stable channel of the latest NixOS
|
|
# release.
|
|
|
|
# Tracking nixos-unstable as of 2021-09-24.
|
|
unstableHashes = {
|
|
commit = "51bcdc4cdaac48535dabf0ad4642a66774c609ed";
|
|
sha256 = "0zpf159nlpla6qgxfgb2m3c2v09fz8jilc21zwymm59qrq6hxscm";
|
|
};
|
|
|
|
# Tracking nixos-21.05 as of 2021-09-22.
|
|
stableHashes = {
|
|
commit = "83413f47809790e4ca012e314e7782adeae36cf2";
|
|
sha256 = "0md5ynzxaw9gx81gh4d0120yjb0jrcydvxf0nsym402qfbhpchx0";
|
|
};
|
|
|
|
# import the nixos-unstable package set, or optionally use the
|
|
# source (e.g. a path) specified by the `nixpkgsBisectPath`
|
|
# argument. This is intended for use-cases where the depot is
|
|
# bisected against nixpkgs to find the root cause of an issue in a
|
|
# channel bump.
|
|
nixpkgsSrc = externalArgs.nixpkgsBisectPath or (fetchTarball {
|
|
url = "https://github.com/NixOS/nixpkgs/archive/${unstableHashes.commit}.tar.gz";
|
|
sha256 = unstableHashes.sha256;
|
|
});
|
|
|
|
stableNixpkgsSrc = fetchTarball {
|
|
url = "https://github.com/NixOS/nixpkgs/archive/${stableHashes.commit}.tar.gz";
|
|
sha256 = stableHashes.sha256;
|
|
};
|
|
|
|
# Stable package set is imported, but not exposed, to overlay
|
|
# required packages into the unstable set.
|
|
stableNixpkgs = import stableNixpkgsSrc {};
|
|
|
|
# Overlay for packages that should come from the stable channel
|
|
# instead (e.g. because something is broken in unstable).
|
|
stableOverlay = self: super: {
|
|
# awscli2 broken in unstable (nixpkgs#138470)
|
|
awscli2 = stableNixpkgs.awscli2;
|
|
};
|
|
|
|
# Overlay to expose the nixpkgs commits we are using to other Nix code.
|
|
commitsOverlay = _: _: {
|
|
nixpkgsCommits = {
|
|
unstable = unstableHashes.commit;
|
|
stable = stableHashes.commit;
|
|
};
|
|
};
|
|
in import nixpkgsSrc {
|
|
config.allowUnfree = true;
|
|
config.allowBroken = true;
|
|
overlays = [
|
|
commitsOverlay
|
|
stableOverlay
|
|
depot.third_party.overlays.haskell
|
|
depot.third_party.overlays.emacs
|
|
depot.third_party.overlays.tvl
|
|
depot.third_party.overlays.ecl-static
|
|
];
|
|
}
|