3196fe0143
There's various bits and pieces in tvix-cli that use both the store and evaluator, as well as nix-compat. For example, builtins.derivation, as well as the reference scanning implementation. This "glue code" currently isn't accessible from anywhere else, but it'd be very useful if it were. Move it out into a `glue` crate, and make `tvix-cli` a consumer of it. All the KnownPaths setup and passing around, as well as NIX_PATH handling is also something that should probably be moved into the glue crate as well, but that's something left for a future CL. Change-Id: I080ed3d1825ab23790666486840f301f00856277 Reviewed-on: https://cl.tvl.fyi/c/depot/+/9908 Autosubmit: flokli <flokli@flokli.de> Tested-by: BuildkiteCI Reviewed-by: raitobezarius <tvl@lahfa.xyz>
53 lines
1.4 KiB
Nix
53 lines
1.4 KiB
Nix
# SPDX-License-Identifier: LGPL-2.1
|
|
#
|
|
# This file is vendored from C++ Nix, as it needs to be bundled with
|
|
# an evaluator to be able to evaluate nixpkgs.
|
|
#
|
|
# Source: https://github.com/NixOS/nix/blob/2.3.16/corepkgs/fetchurl.nix
|
|
|
|
{ system ? "" # obsolete
|
|
, url
|
|
, hash ? "" # an SRI hash
|
|
|
|
# Legacy hash specification
|
|
, md5 ? ""
|
|
, sha1 ? ""
|
|
, sha256 ? ""
|
|
, sha512 ? ""
|
|
, outputHash ? if hash != "" then hash else if sha512 != "" then sha512 else if sha1 != "" then sha1 else if md5 != "" then md5 else sha256
|
|
, outputHashAlgo ? if hash != "" then "" else if sha512 != "" then "sha512" else if sha1 != "" then "sha1" else if md5 != "" then "md5" else "sha256"
|
|
|
|
, executable ? false
|
|
, unpack ? false
|
|
, name ? baseNameOf (toString url)
|
|
}:
|
|
|
|
derivation {
|
|
builder = "builtin:fetchurl";
|
|
|
|
# New-style output content requirements.
|
|
inherit outputHashAlgo outputHash;
|
|
outputHashMode = if unpack || executable then "recursive" else "flat";
|
|
|
|
inherit name url executable unpack;
|
|
|
|
system = "builtin";
|
|
|
|
# No need to double the amount of network traffic
|
|
preferLocalBuild = true;
|
|
|
|
impureEnvVars = [
|
|
# We borrow these environment variables from the caller to allow
|
|
# easy proxy configuration. This is impure, but a fixed-output
|
|
# derivation like fetchurl is allowed to do so since its result is
|
|
# by definition pure.
|
|
"http_proxy"
|
|
"https_proxy"
|
|
"ftp_proxy"
|
|
"all_proxy"
|
|
"no_proxy"
|
|
];
|
|
|
|
# To make "nix-prefetch-url" work.
|
|
urls = [ url ];
|
|
}
|