c05bf02a85
This bumps Gerrit to 3.10.0, and also introduces a new mechanism for building it that should hopefully have some more stable hashes than the previous bodgery. In this world, we only cache what we explicitly want to. There are some hooks implemented for `rules_java` and `rules_nodejs` (before version 6) that force use of local binaries; this means we can drop the use of the FHSUserEnv and use the java and nodejs binaries provided by nixpkgs instead. detzip is deleted; it hasn't been used in yonks. We also add https://gerrit-review.googlesource.com/c/gerrit/+/431977, which bumps the SSHd version so that we can have U2F-based SSH keys. Change-Id: Ie12a9a33bbb1e4bd96aa252580aca3b8bc4a1205 Reviewed-on: https://cl.tvl.fyi/c/depot/+/11963 Reviewed-by: lukegb <lukegb@tvl.fyi> Autosubmit: lukegb <lukegb@tvl.fyi> Tested-by: BuildkiteCI
53 lines
1.1 KiB
Nix
53 lines
1.1 KiB
Nix
{ stdenvNoCC
|
|
, lib
|
|
, makeSetupHook
|
|
, fetchFromGitHub
|
|
, coreutils
|
|
, gnugrep
|
|
, nodejs
|
|
, yarn
|
|
, git
|
|
, cacert
|
|
}:
|
|
let
|
|
rulesNodeJS = stdenvNoCC.mkDerivation rec {
|
|
pname = "bazelbuild-rules_nodejs";
|
|
version = "5.8.5";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "bazelbuild";
|
|
repo = "rules_nodejs";
|
|
rev = version;
|
|
hash = "sha256-6UbYRrOnS93+pK4VI016gQZv2jLCzkJn6wJ4vZNCNjY=";
|
|
};
|
|
|
|
dontBuild = true;
|
|
|
|
postPatch = ''
|
|
shopt -s globstar
|
|
for i in **/*.bzl **/*.sh **/*.cjs; do
|
|
substituteInPlace "$i" \
|
|
--replace-quiet '#!/usr/bin/env bash' '#!${stdenvNoCC.shell}' \
|
|
--replace-quiet '#!/bin/bash' '#!${stdenvNoCC.shell}'
|
|
done
|
|
sed -i '/^#!/a export PATH=${lib.makeBinPath [ coreutils gnugrep ]}:$PATH' internal/node/launcher.sh
|
|
'';
|
|
|
|
installPhase = ''
|
|
cp -R . $out
|
|
'';
|
|
};
|
|
in makeSetupHook {
|
|
name = "bazelbuild-rules_nodejs-5-hook";
|
|
propagatedBuildInputs = [
|
|
nodejs
|
|
yarn
|
|
git
|
|
cacert
|
|
];
|
|
substitutions = {
|
|
inherit nodejs yarn cacert rulesNodeJS;
|
|
local_node = ./local_node;
|
|
local_yarn = ./local_yarn;
|
|
};
|
|
} ./setup-hook.sh
|