feat: add support for untagged frames

Should cover egress & ingress.

Signed-off-by: Raito Bezarius <masterancpp@gmail.com>

.forgejo/workflows/build.yaml

@@ -38,3 +38,13 @@ jobs:
         run: |
           # Enter the shell
           nix-build ci.nix -A wlan
+
+  test_shell_customization:
+    runs-on: nix
+    steps:
+      - uses: actions/checkout@v3
+
+      - name: Build VM QEMU MIPS
+        run: |
+          # Enter the shell
+          nix-build ci.nix -A custom-shell

lib/eval-config.nix

@@ -12,6 +12,7 @@ in
     "${modulesPath}/hardware.nix"
     "${modulesPath}/base.nix"
     "${modulesPath}/busybox.nix"
+    "${modulesPath}/iproute2.nix"
     "${modulesPath}/hostname.nix"
     "${modulesPath}/kernel"
     "${modulesPath}/s6"

modules/all-modules.nix

@@ -4,9 +4,10 @@
 
 {
   imports = [
-   ./base.nix
+    ./base.nix
    ./bridge
    ./busybox.nix
+   ./iproute2.nix
    ./dhcp6c
    ./jitter-rng
    ./dnsmasq

modules/base.nix

@@ -4,11 +4,13 @@
 
 { lib, pkgs, config, ...}:
 let
-  inherit (lib) mkEnableOption mkOption types isDerivation hasAttr ;
+  inherit (lib) mkEnableOption mkOption types isDerivation hasAttr concatStringsSep mapAttrsToList;
   inherit (pkgs.pseudofile) dir symlink;
   inherit (pkgs.liminix.networking) address interface;
   inherit (pkgs.liminix.services) bundle;
 
+  # TODO: escape shell argument.
+  exportVar = name: value: "export ${name}=\"${value}\"";
   type_service = pkgs.liminix.lib.types.service;
 
 in {
@@ -22,6 +24,24 @@ in {
           /run/current-system, we just add the paths in /etc/profile
         '';
       };
+
+      environmentVariables = mkOption {
+        type = types.attrsOf types.str;
+        description = ''
+          Attribute set of environment variables to make available
+          in a login shell.
+
+          The value is assumed to be escaped and the name to be valid.
+        '';
+      };
+
+      prompt = mkOption {
+        type = types.str;
+        default = "$(whoami)@$(hostname) # ";
+        description = ''
+          Prompt string (PS1) for the shell.
+        '';
+      };
     };
     services = mkOption {
       type = types.attrsOf type_service;
@@ -110,7 +130,9 @@ in {
     nixpkgs.buildPlatform = lib.mkDefault builtins.currentSystem;
 
     defaultProfile.packages = with pkgs;
-      [ s6 s6-init-bin execline s6-linux-init s6-rc ];
+      [ s6 s6-init-bin execline s6-linux-init s6-rc iproute2 ];
+    # Set the useful PS1 prompt by default.
+    defaultProfile.environmentVariables.PS1 = lib.mkDefault config.defaultProfile.prompt;
 
     boot.commandLine = [
       "panic=10 oops=panic init=/bin/init loglevel=8"
@@ -181,9 +203,10 @@ in {
       etc = let
         profile = symlink
           (pkgs.writeScript ".profile" ''
-           PATH=${lib.makeBinPath config.defaultProfile.packages}:/bin
+            PATH=${lib.makeBinPath config.defaultProfile.packages}:/bin
             export PATH
-            '');
+            ${concatStringsSep "\n" (mapAttrsToList exportVar config.defaultProfile.environmentVariables)}
+          '');
       in dir {
         inherit profile;
         ashrc = profile;

modules/bridge/default.nix

@@ -9,8 +9,7 @@
 
 { lib, pkgs, config, ...}:
 let
-  inherit (lib) mkOption types;
+  inherit (lib) mkOption types mkEnableOption;
-  inherit (pkgs.liminix.services) oneshot;
   inherit (pkgs) liminix;
 in
 {
@@ -35,6 +34,20 @@ in
         default = null;
         description = "reuse mac address from an existing interface service";
       };
+
+      untagged = {
+        enable = mkEnableOption "untagged frames on port VID";
+        pvid = mkOption {
+          type = types.nullOr types.int;
+          default = null;
+          description = "Port VLAN ID for egress untagged frames";
+        };
+        default-pvid = mkOption {
+          type = types.int;
+          default = 0;
+          description = "Default PVID for ingress untagged frames, defaults to 0, which disable untagged frames for ingress";
+        };
+      };
     };
     members = config.system.callService ./members.nix {
       primary = mkOption {

modules/bridge/primary.nix

@@ -3,17 +3,22 @@
 , ifwait
 , lib
 }:
-{ ifname, macAddressFromInterface ? null } :
+{ ifname, macAddressFromInterface ? null, untagged } :
 let
-  inherit (liminix.services) bundle oneshot;
+  inherit (liminix.services) oneshot;
-  inherit (lib) mkOption types optional;
+  inherit (lib) optional optionalString;
+  # This enables vlan_filtering if we do make use of it.
+  extra = if untagged.enable then " vlan_filtering 1 vlan_default_pvid ${toString untagged.default-pvid}" else "";
 in oneshot rec {
   name = "${ifname}.link";
   up = ''
     ${if macAddressFromInterface == null then
-      "ip link add name ${ifname} type bridge"
+      "ip link add name ${ifname} type bridge${extra}"
       else
-      "ip link add name ${ifname} address $(output ${macAddressFromInterface} ether) type bridge"}
+      "ip link add name ${ifname} address $(output ${macAddressFromInterface} ether) type bridge${extra}"}
+
+      ${optionalString untagged.enable 
+        "bridge vlan add vid ${toString untagged.pvid} dev ${ifname} pvid untagged self"}
 
       (in_outputs ${name}
         echo ${ifname} > ifname

modules/busybox.nix

@@ -37,7 +37,7 @@ let
     "comm" "cp" "cpio" "cut" "date" "dhcprelay" "dd" "df" "dirname" "dmesg"
     "du" "echo" "egrep" "env" "expand" "expr" "false" "fdisk" "fgrep" "find"
     "free" "fuser" "grep" "gunzip" "gzip" "head" "hexdump" "hostname" "hwclock"
-    "ifconfig" "ip" "ipaddr" "iplink" "ipneigh" "iproute" "iprule" "kill"
+    "ifconfig" "ipneigh" "kill"
     "killall" "killall5" "less" "ln" "ls" "lsattr" "lsof" "md5sum" "mkdir"
     "mknod" "mktemp" "mount" "mv" "nc" "netstat" "nohup" "od" "pgrep" "pidof"
     "ping" "ping6" "pkill" "pmap" "printenv" "printf" "ps" "pwd" "readlink"

modules/hostname.nix

@@ -1,7 +1,6 @@
 { lib, pkgs, config, ...}:
 let
   inherit (lib) mkOption types;
-  inherit (pkgs.liminix.services) oneshot;
 in {
   options = {
     hostname = mkOption {
@@ -12,12 +11,21 @@ in {
       default = "liminix";
       type = types.nonEmptyStr;
     };
-  };
+    hostname-script = mkOption {
-  config = {
+      description = ''
-    services.hostname = oneshot {
+        Script that outputs the system hostname on stdin.
-      name = "hostname-${builtins.substring 0 12 (builtins.hashString "sha256" config.hostname)}";
+      '';
-      up = "echo ${config.hostname} > /proc/sys/kernel/hostname";
+      default = pkgs.writeScript "hostname-gen" ''
-      down = "true";
+        #!/bin/sh
+        echo ${config.hostname}
+      '';
+      defaultText = ''
+        pkgs.writeScript "hostname-gen" '''
+        #!/bin/sh
+        echo ''${config.hostname}
+      '''
+      '';
+      type = types.package;
     };
   };
 }

modules/iproute2.nix

@@ -0,0 +1,28 @@
+{ config, pkgs, lib, ... }:
+let
+  inherit (lib) mkEnableOption mkPackageOption mkIf genAttrs;
+  inherit (pkgs.pseudofile) dir symlink;
+  cfg = config.programs.iproute2;
+  minimalPrograms = [
+    "ip"
+    "devlink"
+    "ss"
+    "bridge"
+    "genl"
+    "ifstat"
+    "nstat"
+  ];
+  links = genAttrs minimalPrograms (p: symlink "${cfg.package}/bin/${p}");
+in
+{
+  options.programs.iproute2 = {
+    enable = mkEnableOption "the iproute2 programs instead of busybox variants";
+    package = mkPackageOption pkgs "iproute2" { };
+  };
+
+  config = mkIf cfg.enable {
+    filesystem = dir {
+      bin = dir links;
+    };
+  };
+}

modules/outputs/initramfs.nix

@@ -54,7 +54,7 @@ in
             mount -t sysfs none /sys
             ${busybox}/bin/sh
           '';
-          refs = pkgs.writeReferencesToFile busybox;
+          refs = pkgs.writeClosure [ busybox ];
         in runCommand "initramfs.cpio" {} ''
           cat << SPECIALS | ${gen_init_cpio}/bin/gen_init_cpio /dev/stdin > out
           dir /proc 0755 0 0

modules/s6/default.nix

@@ -30,6 +30,8 @@ let
     installPhase = ''
       mkdir $out
       cp -r $src $out/scripts
+      substituteInPlace $out/scripts/rc.init \
+        --replace-fail 'config.hostname' "${config.hostname-script}"
       chmod -R +w $out
     '';
   };

modules/s6/scripts/rc.init

@@ -36,6 +36,7 @@ fi
 ### (replace /run/service with your scandir)
 s6-rc-init -d -c /etc/s6-rc/compiled /run/service
 
+config.hostname > /proc/sys/kernel/hostname
 
 ### 2. Starting the wanted set of services
 ### This is also called every time you change runlevels with telinit.

modules/vlan/default.nix

@@ -33,6 +33,11 @@ in
       description = "VLAN identifier (VID) in range 1-4094";
       type = types.str;
     };
+    untagged.egress = mkOption {
+      description = "Whether packets from this interface will go out *untagged*";
+      type = types.bool;
+      default = false;
+    };
   };
   config.kernel.config = {
     VLAN_8021Q = "y";

modules/vlan/service.nix

@@ -2,13 +2,15 @@
   liminix
 , lib
 }:
-{ ifname, primary, vid } :
+{ ifname, primary, vid, untagged } :
 let
+  inherit (lib) optionalString;
   inherit (liminix.services) oneshot;
 in oneshot rec {
   name = "${ifname}.link";
   up = ''
     ip link add link $(output ${primary} ifname) name ${ifname} type vlan id ${vid}
+    ${optionalString untagged.egress "bridge vlan add dev ${ifname} vid ${toString untagged.vid} pvid untagged master"}
     ${liminix.networking.ifup name ifname}
     (in_outputs ${name}
      echo ${ifname} > ifname

overlay.nix

@@ -141,7 +141,9 @@ extraPkgs // {
            repo = "hostapd";
            rev = "hostap-liminix-integration";
            hash = "sha256-5Xi90keCHxvuKR5Q7STuZDzuM9h9ac6aWoXVQYvqkQI=";
-        };
+         };
+        # Do not take any patch.
+        patches = [];
         extraConfig = "";
         configurePhase = ''
           cat > hostapd/defconfig <<EOF
@@ -184,6 +186,7 @@ extraPkgs // {
            rev = "hostap-liminix-integration";
            hash = "sha256-5Xi90keCHxvuKR5Q7STuZDzuM9h9ac6aWoXVQYvqkQI=";
       };
+      patches = [];
       extraConfig = "";
       configurePhase = ''
         cat > hostapd/defconfig <<EOF
@@ -194,6 +197,30 @@ extraPkgs // {
     });
   in h.override { openssl = null; sqlite = null; };
 
+  libnl = prev.libnl.override {
+    graphviz = null;
+  };
+
+  iproute2 =
+  let i = prev.iproute2.overrideAttrs (old: {
+    postInstall = ''
+      ${(old.postInstall or "")}
+      non_necessary_binaries=("tc" "rdma" "dcb" "tipc" "vdpa")
+      for needless_binary in "''${non_necessary_binaries[@]}"; do
+        echo "Removing unnecessary binary $out/sbin/$needless_binary"
+        rm "$out/sbin/$needless_binary"
+      done
+      # No man
+      rm -rf "$out/share"
+      # Remove all the data about distributions for tc.
+      rm -rf "$out/lib"
+    '';
+  });
+  # Don't bring ebpf stuff to the table.
+  # We also remove tc so we can drop iptables as well.
+  # Let's try to kill `db` as well.
+  in i.override { elfutils = null; iptables = null; db = null; };
+
   wpa_supplicant = prev.wpa_supplicant.override {
     dbusSupport = false;
     withPcsclite = false;

pkgs/initramfs-peek/default.nix

@@ -3,7 +3,7 @@
 , pkgsBuildBuild
 , runCommand
 , cpio
-, writeReferencesToFile
+, writeClosure
 , writeScript
 } :
 let
@@ -18,7 +18,7 @@ let
     mount -t sysfs none /sys
     ${busybox}/bin/sh
   '';
-  refs = writeReferencesToFile busybox;
+  refs = writeClosure [ busybox ];
 in runCommand "initramfs.cpio" { } ''
   cat << SPECIALS | ${gen_init_cpio}/bin/gen_init_cpio /dev/stdin > out
   dir /proc 0755 0 0

pkgs/levitate/default.nix

@@ -2,6 +2,7 @@
   writeScriptBin
 , writeScript
 , systemconfig
+, stdenv
 , execline
 , lib
 , config ? {}
@@ -56,11 +57,19 @@ let
       };
       eval = lib.evalModules {
         modules = [
-          { _module.args = { inherit pkgs; inherit (pkgs) lim; }; }
           ../../modules/base.nix
           ../../modules/users.nix
           ../../modules/busybox.nix
+          ../../modules/hostname.nix
+          ../../modules/misc/assertions.nix
+          ../../modules/nixpkgs.nix
           base
+          {
+            # Inherit from that target system host platform.
+            nixpkgs.hostPlatform = stdenv.hostPlatform;
+            # Force our own package set.
+            nixpkgs.pkgs = lib.mkForce pkgs;
+          }
           ({ ... } : paramConfig)
           ../../modules/s6
         ];

tests/ci.nix

@@ -10,4 +10,5 @@
   tftpboot = import ./tftpboot/test.nix;
   updown = import ./updown/test.nix;
   inout = import ./inout/test.nix;
+  custom-shell = import ./custom-shell/test.nix;
 }

tests/custom-shell/check-prompt.expect

@@ -0,0 +1,7 @@
+set timeout 60
+
+spawn socat unix-connect:vm/console -
+expect {
+  "root@liminix blah blah > " { exit 0 }
+  timeout { exit 1 }
+}

tests/custom-shell/configuration.nix

@@ -0,0 +1,13 @@
+{ config, pkgs, lib, ... } :
+let
+  inherit (pkgs.liminix.networking) interface address hostapd route dnsmasq;
+  inherit (pkgs.liminix.services) oneshot longrun bundle target;
+in rec {
+  imports = [
+    ../../modules/network
+  ];
+
+  defaultProfile.prompt = "$(whoami)@$(hostname) blah blah > ";
+
+  defaultProfile.packages = with pkgs; [ ];
+}

tests/custom-shell/test.nix

@@ -0,0 +1,21 @@
+{
+  liminix
+, nixpkgs
+}:
+let img = (import liminix {
+      inherit nixpkgs;
+      device = import "${liminix}/devices/qemu/";
+      liminix-config = ./configuration.nix;
+    }).outputs.default;
+    pkgs = import nixpkgs { overlays = [(import ../../overlay.nix)]; };
+in pkgs.runCommand "check" {
+  nativeBuildInputs = with pkgs; [
+    expect socat
+  ] ;
+} ''
+. ${../test-helpers.sh}
+
+mkdir vm
+${img}/run.sh --background ./vm
+expect ${./check-prompt.expect} |tee output && mv output $out
+''