infrastructure/machines/vault01/k-radius/packages/pykanidm.nix

{
  lib,
  fetchFromGitHub,
  python3,
  pydantic,
}:

let
  pname = "kanidm";
  version = "0.0.3";
in
python3.pkgs.buildPythonPackage {
  inherit pname version;
  format = "pyproject";

  disabled = python3.pythonOlder "3.8";

  src =
    (fetchFromGitHub {
      owner = pname;
      repo = pname;
      # Latest 1.1.0-rc.15 tip
      rev = "a5ca8018e3a636dbb0a79b3fd869db059d92979d";
      hash = "sha256-PFGoeGn7a/lVR6rOmOKA3ydAoo3/+9RlkwBAKS22Psg=";
    })
    + "/pykanidm";

  nativeBuildInputs = with python3.pkgs; [ poetry-core ];

  propagatedBuildInputs = with python3.pkgs; [
    aiohttp
    pydantic
    toml
    (authlib.overridePythonAttrs (_: {
      doCheck = false;
    }))
  ];

  doCheck = false;

  pythonImportsCheck = [ "kanidm" ];

  meta = with lib; {
    description = "Kanidm client library";
    homepage = "https://github.com/kanidm/kanidm/tree/master/pykanidm";
    license = licenses.mpl20;
    maintainers = with maintainers; [
      arianvp
      hexa
    ];
  };
}