infrastructure/modules/dgn-netbox-agent/default.nix

{
  config,
  lib,
  nodeMeta,
  ...
}:
let
  inherit (config.networking) hostName domain;
in
{

  options.dgn-netbox-agent = {
    enable = lib.mkEnableOption "DGNum netbox agent setup." // {
      default = true;
    };
  };

  config = lib.mkIf config.dgn-netbox-agent.enable {
    nixpkgs.overlays = [
      (_: super: {
        netbox-agent = super.netbox-agent.overrideAttrs (old: {
          patches = (old.patches or [ ]) ++ [ ./01-batch-filter.patch ];
        });
      })
    ];

    services.netbox-agent = {
      enable = true;

      settings = {
        netbox.url = "https://netbox.dgnum.eu/";
        network.ignore_interfaces = "(lo|dummy.*|docker.*|podman.*)";
        register = true;
        update_all = true;
        virtual = {
          enabled = nodeMeta.vm-cluster != null;
          cluster_name = nodeMeta.vm-cluster;
        };
        purge_old_devices = true;
        hostname_cmd = "echo ${hostName}.${domain}";
        datacenter_location = {
          driver = "cmd:echo ${nodeMeta.site}";
          regex = "(.*)";
        };
        device = {
          tags = "netbox-agent";
          # Default role
          server_role = "Staging infra";
        };
      };
      randomizedDelaySec = "3h";
      environmentFile = config.age.secrets."netbox-agent".path;
    };
    age-secrets.sources = [ ./. ];
  };
}