forked from DGNum/infrastructure
Tom Hubrecht
88d9b8c3e3
Signed-off-by: Tom Hubrecht <tom.hubrecht@dgnum.eu> Acked-by: Ryan Lahfa <ryan.lahfa@dgnum.eu> Acked-by: Maurice Debray <maurice.debray@dgnum.eu> Acked-by: Lubin Bailly <lubin.bailly@dgnum.eu> Acked-by: Jean-Marc Gailis <jean-marc.gailis@dgnum.eu> as the legal authority, at the time of writing, in DGNum. Acked-by: Elias Coppens <elias.coppens@dgnum.eu> as a member, at the time of writing, of the DGNum executive counsel.
58 lines
1.2 KiB
Nix
58 lines
1.2 KiB
Nix
# SPDX-FileCopyrightText: 2024 Tom Hubrecht <tom.hubrecht@dgnum.eu>
|
|
#
|
|
# SPDX-License-Identifier: EUPL-1.2
|
|
|
|
{
|
|
config,
|
|
lib,
|
|
meta,
|
|
name,
|
|
nodeMeta,
|
|
...
|
|
}:
|
|
|
|
let
|
|
inherit (lib) mapAttrs' mkEnableOption mkIf;
|
|
|
|
net' = meta.network.${name};
|
|
|
|
mkAddress = { address, prefixLength, ... }: "${address}/${builtins.toString prefixLength}";
|
|
mkRoute = gateway: {
|
|
routeConfig = {
|
|
Gateway = gateway;
|
|
GatewayOnLink = true;
|
|
};
|
|
};
|
|
|
|
mkInterface = interface: net: {
|
|
name = "10-${interface}";
|
|
value = {
|
|
name = interface;
|
|
address = builtins.map mkAddress (net.ipv4 ++ net.ipv6);
|
|
routes = builtins.map mkRoute net.gateways;
|
|
|
|
inherit (net) DHCP dns;
|
|
};
|
|
};
|
|
|
|
cfg = config.dgn-network;
|
|
in
|
|
{
|
|
options.dgn-network.enable = mkEnableOption "automatic network configuration based on metadata" // {
|
|
default = true;
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
networking = {
|
|
inherit (net') hostId;
|
|
|
|
hostName = name;
|
|
domain = "${nodeMeta.site}.infra.dgnum.eu";
|
|
useNetworkd = true;
|
|
|
|
firewall.logRefusedConnections = false;
|
|
};
|
|
|
|
systemd.network.networks = mapAttrs' mkInterface net'.interfaces;
|
|
};
|
|
}
|