feat(cas-eleves): Update to latest version

machines/web02/cas-eleves/default.nix

@@ -19,6 +19,8 @@ let
     ps.psycopg
 
     # Local packages
+    (ps.callPackage ./packages/django-browser-reload { })
+    (ps.callPackage ./packages/django-bulma-forms { })
     (ps.callPackage ./packages/django-cas-server { })
     (ps.callPackage ./packages/loadcredential { })
   ]);
@@ -48,10 +50,13 @@ in
 
 {
   systemd.services = {
-    "django-cas-eleves" = {
+    django-cas-eleves = {
       description = "ENS CAS server";
       wantedBy = [ "multi-user.target" ];
-      after = [ "network.target" ];
+      after = [
+        "network.target"
+        "postgresql.service"
+      ];
 
       serviceConfig = {
         DynamicUser = true;
@@ -78,6 +83,31 @@ in
         gunicorn app.wsgi --pythonpath ${sources.cas-eleves} -b 127.0.0.1:${builtins.toString port} --workers=2 --threads=4
       '';
     };
+
+    cas-eleves-cleanup = {
+      description = "Periodic cleanup of cas_server database";
+
+      startAt = "daily";
+
+      serviceConfig = {
+        Type = "oneshot";
+
+        LoadCredential = mapAttrsToList (name: value: "${name}:${value}") {
+          SECRET_KEY = config.age.secrets."cas_eleves-secret_key_file".path;
+        };
+        StateDirectory = "django-cas-eleves";
+        User = "cas_server";
+        WorkingDirectory = sources.cas-eleves;
+      };
+
+      path = [ pythonEnv ];
+
+      script = ''
+        python3 manage.py clearsessions
+        python3 manage.py cas_clean_sessions
+        python3 manage.py cas_clean_tickets
+      '';
+    };
   };
 
   services = {

machines/web02/cas-eleves/packages/django-browser-reload/default.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  wheel,
+  asgiref,
+  django,
+}:
+
+buildPythonPackage rec {
+  pname = "django-browser-reload";
+  version = "1.12.1";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "adamchainz";
+    repo = "django-browser-reload";
+    rev = version;
+    hash = "sha256-IDIkAl6YYI3isDvpzCtAu4fLSr2gbjEvVW+K1WBDPbo=";
+  };
+
+  nativeBuildInputs = [
+    setuptools
+    wheel
+  ];
+
+  propagatedBuildInputs = [
+    asgiref
+    django
+  ];
+
+  pythonImportsCheck = [ "django_browser_reload" ];
+
+  meta = with lib; {
+    description = "Automatically reload your browser in development";
+    homepage = "https://github.com/adamchainz/django-browser-reload";
+    changelog = "https://github.com/adamchainz/django-browser-reload/blob/${src.rev}/CHANGELOG.rst";
+    license = licenses.mit;
+    maintainers = [ ]; # with maintainers; [ thubrecht ];
+  };
+}

machines/web02/cas-eleves/packages/django-bulma-forms/default.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchgit,
+  setuptools,
+  setuptools-scm,
+  wheel,
+  django,
+}:
+
+buildPythonPackage rec {
+  pname = "django-bulma-forms";
+  version = "0.1.4";
+  pyproject = true;
+
+  src = fetchgit {
+    url = "https://git.hubrecht.ovh/hubrecht/django-bulma-forms";
+    rev = "v${version}";
+    hash = "sha256-4KTMXx3YxDxB4/YH14pJnNYtpOGXeDmD+gcbrUHwD/w=";
+  };
+
+  nativeBuildInputs = [
+    setuptools
+    setuptools-scm
+    wheel
+  ];
+
+  propagatedBuildInputs = [ django ];
+
+  meta = with lib; {
+    description = "";
+    homepage = "https://git.hubrecht.ovh/hubrecht/django-bulma-forms";
+    license = licenses.eupl12;
+    maintainers = [ ]; # with maintainers; [ thubrecht ];
+  };
+}