infrastructure/machines/compute01/ds-fr/package/default.nix

{ lib, stdenv, fetchpatch, fetchFromGitHub, fetchYarnDeps, yarn, fixup_yarn_lock
, nodejs, ruby_3_2, bundlerEnv, logDir ? "/var/log/ds-fr"
, dataDir ? "/var/lib/ds-fr", initialDeploymentDate ? "17941030" }:

let
  pname = "ds-fr";
  meta = import ./meta.nix;

  inherit (meta) version;

  src = fetchFromGitHub {
    owner = "demarches-simplifiees";
    repo = "demarches-simplifiees.fr";
    rev = version;
    hash = meta.src-hash;
  };

  rubyEnv = bundlerEnv {
    name = "env-${pname}";
    gemdir = ./rubyEnv;
    ruby = ruby_3_2;
    gemset = (import ./rubyEnv/gemset.nix) // {
      bundler = {
        groups = [ "default" ];
        platforms = [ ];
        source = {
          remotes = [ "https://rubygems.org" ];
          sha256 = "deeQ3fNwcSiGSO/yeB2yoTniRq2gHW8WueprXoPX6Jk=";
          type = "gem";
        };
        version = "2.3.11";
      };
    };
  };

  dsModules = stdenv.mkDerivation {
    pname = "${pname}-modules";
    inherit src version;

    offlineCache = fetchYarnDeps {
      yarnLock = "${src}/yarn.lock";
      hash = meta.deps-hash;
    };

    buildInputs = [ rubyEnv ];
    nativeBuildInputs = [ fixup_yarn_lock nodejs yarn rubyEnv.wrappedRuby ];

    RAILS_ENV = "production";
    NODE_ENV = "dev";

    patches = [
      # Disable functionnalities as we only precompile assets
      ./patches/build.patch
    ] ++ dgn-patches;

    OTP_SECRET_KEY = "precompile_placeholder";
    SECRET_KEY_BASE = "precompile_placeholder";
    APP_HOST = "precompile_placeholder";

    buildPhase = ''
      export HOME=$(mktemp -d)
      yarn config --offline set yarn-offline-mirror $offlineCache
      fixup_yarn_lock yarn.lock
      yarn install --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive

      patchShebangs node_modules/
      patchShebangs bin/

      bin/rake assets:precompile

      yarn cache clean --offline
      rm -rf node_modules/
    '';

    installPhase = ''
      mkdir -p $out/public
      cp -r public/* $out/public
    '';
  };

  dgn-patches = builtins.map ({ id, hash ? lib.fakeHash }:
    fetchpatch {
      url =
        "https://git.dgnum.eu/DGNum/demarches-normaliennes/commit/${id}.patch";
      inherit hash;
    }) [
      # remplacement l'arrache de quelques logos vers versions DGNum
      {
        id = "05d34a880ebb34265ebbcac0a83625b3a976c348";
        hash = "sha256-3VTBom8Lz6F/NXvjLzdhBddXS5FerV5eNHUkDPBDeD8=";
      }
      # ajout des NDD usuels ENS et DGNum pour autoriser les changements d'adresse mail
      {
        id = "bc4742aaacb174a55a08baae5f354ada3fba4577";
        hash = "sha256-LShcRzj/lnFQyJtc9+RxNQq8tsCcdYrwhe2BjqLr1pQ=";
      }
      # correction des svg des logos DGNum et DN
      {
        id = "ee474712a3e50d186acd8bbb52f60c1e4fee2f81";
        hash = "sha256-yoPCZOPPOk84n2oAISzjzJ8n3eWtsYqPglayRKcJGII=";
      }
    ];

in stdenv.mkDerivation {
  name = "demarches-simplifiees.fr-${version}";

  inherit src;

  buildInputs = [ rubyEnv ];
  propagatedBuildInputs = [ rubyEnv.wrappedRuby ];

  patches = [
    ./patches/replay_routing_engine_for_a_cloned_procedure.patch
    ./patches/smtp_settings.patch
    ./patches/garage.patch
    ./patches/secrets-fc.patch
    ./patches/uninterlace_png.patch
  ] ++ dgn-patches;

  buildPhase = ''
    rm -rf public
    ln -s ${dsModules}/public/ public

    patchShebangs bin/

    rm -rf log storage
    ln -s ${logDir} log
    ln -s ${dataDir}/tmp tmp
    ln -s ${dataDir}/storage storage

    for f in $(ls lib/tasks/deployment/); do
      [[ ! ${initialDeploymentDate} < $f ]] \
        && rm lib/tasks/deployment/$f;
    done;

    echo "Removed unused data migrations"
  '';

  installPhase = ''
    mkdir -p $out
    cp -r * $out/
  '';

  passthru = {
    inherit rubyEnv;
    ruby = rubyEnv.wrappedRuby;
  };

  meta = with lib; {
    description = "Dématérialiser et simplifier les démarches administratives";
    homepage =
      "https://github.com/demarches-simplifiees/demarches-simplifiees.fr";
    license = licenses.agpl3Only;
    maintainers = with maintainers; [ thubrecht ];
  };
}