feat(pixiecore): enable for milieu

machines/hackens-milieu/_configuration.nix

@@ -18,6 +18,7 @@
     ./system.nix
     ./users.nix
     ./vim.nix
+    ./pixiecore
   ];
 
   boot.loader.efi.canTouchEfiVariables = true;

machines/hackens-milieu/pixiecore/default.nix

@@ -0,0 +1,19 @@
+{ pkgs, config, ... }:
+let
+  net-config = (import (pkgs.path + "/nixos/lib/eval-config.nix") {
+      system = "x86_64-linux";
+      modules = [
+        ./net-config.nix
+        { users.users.root.openssh.authorizedKeys.keyFiles = config.users.users.root.openssh.authorizedKeys.keyFiles; }
+      ];
+  }).config.system.build;
+in
+{
+  services.pixiecore = {
+    enable = true;
+    openFirewall = true;
+    kernel = "${net-config.kernel}/bzImage";
+    initrd = "${net-config.netbootRamdisk}/initrd";
+    cmdLine = "init=${net-config.toplevel}/init loglevel=4";
+  };
+}

machines/hackens-milieu/pixiecore/net-config.nix

@@ -0,0 +1,42 @@
+{ pkgs, config, lib, modulesPath, ... }: {
+  imports = [
+    (modulesPath + "/installer/netboot/netboot-base.nix")
+  ];
+
+  boot.tmp.useTmpfs = true;
+  time.timeZone = "Europe/Paris";
+  i18n.defaultLocale = "en_US.UTF-8";
+  console = {
+    font = "Lat2-Terminus16";
+    keyMap = "fr";
+  };
+
+  environment.systemPackages = with pkgs; [
+    vim
+  ];
+
+  services = {
+    getty.autologinUser = lib.mkForce "root";
+    openssh = {
+      enable = true;
+      settings.PermitRootLogin = "yes";
+    };
+  };
+
+  nix = {
+    nixPath = [
+      "nixpkgs=${builtins.storePath pkgs.path}"
+      "nixos=${builtins.storePath pkgs.path}"
+    ];
+    channel.enable = false;
+    settings.nix-path = config.nix.nixPath;
+    package = pkgs.lix;
+  };
+
+  networking = {
+    hostName = "hackens-net-image";
+    firewall.enable = false;
+  };
+
+  system.stateVersion = "23.11";
+}

machines/hackens-milieu/users.nix

@@ -28,5 +28,4 @@ in
   users.users.root = {
     openssh.authorizedKeys.keyFiles = superadmins;
   };
-
 }