detect arch in kernel and uimage

also move kernel builder to pkgs/

FIXME we need to straighten out the mess in calling
dtb.nix/uimage.nix

pkgs/kernel/default.nix

@@ -11,6 +11,12 @@
 let
   writeConfig = import ./write-kconfig.nix { inherit lib writeText; };
   kconfigFile = writeConfig "kconfig" config;
+  arch = if stdenv.isMips
+         then "mips"
+         else if stdenv.isAarch64
+         then "arm64"
+         else throw "unknown arch";
+
   inherit lib; in
 stdenv.mkDerivation rec {
   name = "kernel";
@@ -28,7 +34,7 @@ stdenv.mkDerivation rec {
     "-I${openssl.dev}/include -L${openssl.out}/lib -L${ncurses.out}/lib";
   PKG_CONFIG_PATH = "./pkgconfig";
   CROSS_COMPILE = stdenv.cc.bintools.targetPrefix;
-  ARCH = "mips";  # kernel uses "mips" here for both mips and mipsel
+  ARCH = arch;
   KBUILD_BUILD_HOST = "liminix.builder";
 
   dontStrip = true;

pkgs/kernel/dtb.nix

@@ -0,0 +1,23 @@
+{
+  stdenv
+, dtc
+, lib
+}:
+{ dts
+, includes
+, commandLine
+}:let
+  cppDtSearchFlags = builtins.concatStringsSep " " (map (f: "-I${f}") includes);
+  dtcSearchFlags = builtins.concatStringsSep " " (map (f: "-i${f}") includes);
+  cmdline = lib.concatStringsSep " " commandLine;
+in stdenv.mkDerivation {
+  name = "dtb";
+  phases = [ "buildPhase" ];
+  nativeBuildInputs = [ dtc ];
+  buildPhase = ''
+    ${stdenv.cc.targetPrefix}cpp -nostdinc -x assembler-with-cpp ${cppDtSearchFlags} -undef -D__DTS__  -o dtb.tmp ${dts}
+    echo '/{ chosen { bootargs = ${builtins.toJSON cmdline}; }; };'  >> dtb.tmp
+    dtc ${dtcSearchFlags} -I dts  -O dtb -o $out dtb.tmp
+    test -e $out
+  '';
+}

pkgs/kernel/uimage.nix

@@ -0,0 +1,59 @@
+{
+  lzma
+, stdenv
+, ubootTools
+, dtc
+, lib
+} :
+let
+  objcopy = "${stdenv.cc.bintools.targetPrefix}objcopy";
+in {
+  kernel
+, commandLine
+, entryPoint
+, extraName ? ""                # e.g. socFamily
+, loadAddress
+, dtb ? null
+} :
+stdenv.mkDerivation {
+  name = "kernel.image";
+  phases = [
+    "preparePhase"
+    (if dtb != null then "dtbPhase" else ":")
+    "buildPhase"
+    "installPhase" ];
+  nativeBuildInputs = [
+    lzma
+    dtc
+    stdenv.cc
+    ubootTools
+  ];
+  preparePhase = ''
+    cp ${kernel} vmlinux.elf; chmod +w vmlinux.elf
+  '';
+  dtbPhase = ''
+    dtc -I dtb -O dts -o tmp.dts ${dtb}
+    echo '/{ chosen { bootargs = ${builtins.toJSON commandLine}; }; };'  >> tmp.dts
+    dtc -I dts -O dtb -o tmp.dtb tmp.dts
+	  ${objcopy} --update-section .appended_dtb=tmp.dtb vmlinux.elf || ${objcopy} --add-section .appended_dtb=${dtb} vmlinux.elf
+  '';
+
+  buildPhase =
+    let arch =
+          # per output of "mkimage -A list". I *think* these
+          # are the same as the kernel arch convention, but
+          # maybe that's coincidence
+          if stdenv.isMips
+          then "mips"
+          else if stdenv.isAarch64
+          then "arm64"
+          else throw "unknown arch";
+    in ''
+      ${objcopy} -O binary -R .reginfo -R .notes -R .note -R .comment -R .mdebug -R .note.gnu.build-id -S vmlinux.elf vmlinux.bin
+      rm -f vmlinux.bin.lzma ; lzma -k -z  vmlinux.bin
+      mkimage -A ${arch} -O linux -T kernel -C lzma -a ${loadAddress} -e ${entryPoint} -n '${lib.toUpper arch} Liminix Linux ${extraName}' -d vmlinux.bin.lzma kernel.uimage
+    '';
+  installPhase = ''
+    cp kernel.uimage $out
+  '';
+}