liminix/modules/systemd/default.nix

{
  pkgs,
  lib,
  config,
  utils,
  ...
}:
let
  inherit (lib)
    mapAttrs'
    nameValuePair
    mkMerge
    mapAttrsToList
    ;
  inherit (pkgs.pseudofile) dir symlink;
  inherit (utils.systemdUtils.lib)
    targetToUnit
    serviceToUnit
    ;

  units-texts = mapAttrs' (
    _: unit:
    nameValuePair unit.name {
      file = unit.text;
      mode = "0644";
    }
  ) config.units;
  units-aliases = mkMerge (
    mapAttrsToList (
      _: unit:
      mkMerge (
        map (aka: {
          ${aka} = symlink "${unit.name}";
        }) (unit.aliases or [ ])
      )
    ) config.units
  );
  units-extraWants = mkMerge (
    mapAttrsToList (
      _: unit:
      mkMerge (
        map (unit2: {
          "${unit2}.wants" = dir {
            ${unit.name} = symlink "../${unit.name}";
          };
        }) (unit.wantedBy or [ ])
      )
    ) config.units
  );
  units-extraUpholds = mkMerge (
    mapAttrsToList (
      _: unit:
      mkMerge (
        map (unit2: {
          "${unit2}.upholds" = dir {
            ${unit.name} = symlink "../${unit.name}";
          };
        }) (unit.upheldBy or [ ])
      )
    ) config.units
  );
  units-extraRequires = mkMerge (
    mapAttrsToList (
      _: unit:
      mkMerge (
        map (unit2: {
          "${unit2}.requires" = dir {
            ${unit.name} = symlink "../${unit.name}";
          };
        }) (unit.requiredBy or [ ])
      )
    ) config.units
  );

in
{
  config = {
    units = {
      default-target = targetToUnit {
        name = "default.target";
        aliases = [];
        wantedBy = [];
        requiredBy = [];
        upheldBy = [];
        unitConfig.Description = "target to boot";
      };
      sysinit-target = targetToUnit {
        name = "sysinit.target";
        aliases = [];
        wantedBy = [];
        requiredBy = [];
        upheldBy = [];
        unitConfig.Description = "sysinit.target";
      };
      agetty = serviceToUnit {
        name = "getty.service";
        aliases = [];
        wantedBy = [ "default.target" ];
        requiredBy = [];
        upheldBy = [];
        environment = {};
        unitConfig = {
          Description = "Serial Shell";
          Before = [ "default.target" ];
        };
        serviceConfig.ExecStart =
          let
            login = pkgs.writeScript "login" ''
              #!/bin/ash
              . /etc/profile
              exec /bin/ash
            '';
          in
          "${pkgs.util-linux}/bin/agetty --login-program ${login} ttyS0";
      };
    };

    kernel.config = {
      CGROUPS = "y";
      DEVTMPFS = "y";
      INOTIFY_USER = "y";
      SIGNALFD = "y";
      TIMERFD = "y";
      EPOLL = "y";
      UNIX = "y";
      SYSFS = "y";
      PROC_FS = "y";
      FHANDLE = "y";
    };
    boot.commandLine = [
      "systemd.log_level=7"
      #"systemd.crash_shell=true"
    ];
    filesystem = dir {
      etc = dir {
        systemd = dir {
          system = dir (mkMerge [
            units-texts
            units-aliases
            units-extraWants
            units-extraUpholds
            units-extraRequires
          ]);
        };
      };
      bin = dir {
        init = symlink "${pkgs.systemd}/bin/init";
      };
    };
  };
}