lab-infra/machines/dns01/lab.dgnum.eu.nix

{ dns, lib, ... }:

let
  inherit (lib) mapAttrs' nameValuePair;
  meta = (import ./../../meta) lib;
in
with dns.lib.combinators;
{
  SOA = {
    nameServer = "dns01.lab.dgnum.eu";
    adminEmail = "dns@dgnum.eu";
    serial = 2019030800;
    retry = 3600;
    minimum = 300;
  };

  NS = [
    "dns01.lab.dgnum.eu."
  ];

  #A = [ "203.0.113.1" ];
  #AAAA = [ "4321:0:1:2:3:4:567:89ab" ];

  subdomains = {
    # Hosted services
    # NOTE: for now manually supplied, in the future automatically filled in
    photoprism = host "129.199.146.101" null;
    immich = host "129.199.146.101" null;

    # Nameservers
    dns01 = host "45.13.104.26" "2a0e:e701:1120:1000:ffff::45.13.104.26";

    # *.infra.beta.dgnum.eu
    infra = {
      subdomains = mapAttrs' (
        host:
        { site, ... }:
        nameValuePair "${host}.${site}" (
          with meta.network.${host}.addresses;
          {
            A = ipv4;
            AAAA = ipv6;

            subdomains = {
              v4.A = ipv4;
              v6.AAAA = ipv6;
            };
          }
        )
      ) meta.nodes;
    };
  };
}