infrastructure/modules/nixos/dgn-node-monitoring.nix

# SPDX-FileCopyrightText: 2024 Maurice Debray <maurice.debray@dgnum.eu>
# SPDX-FileCopyrightText: 2024 Ryan Lahfa <ryan.lahfa@dgnum.eu>
#
# SPDX-License-Identifier: EUPL-1.2

{
  pkgs,
  sources,
  config,
  lib,
  ...
}:
let
  inherit (lib)
    mkEnableOption
    mkIf
    mkOption

    types
    ;
  cfg = config.dgn-node-monitoring;
in

{
  options.dgn-node-monitoring = {
    enable = mkEnableOption "DGNum nodes monitoring (needs a valid netbird tunnel)" // {
      default = true;
    };
    port = mkOption {
      type = types.port;
      default = 9002;
      description = ''
        Port to listen on.
      '';
    };
  };

  imports = [
    "${sources.cgroup-exporter}/nix/module.nix"
  ];

  config = mkIf cfg.enable {
    services.prometheus = {
      exporters = {
        node = {
          enable = true;
          enabledCollectors = [
            "processes"
            "systemd"
          ];
          inherit (cfg) port;
          listenAddress = "0.0.0.0";
        };
        cgroup = {
          enable = true;
          package = pkgs.callPackage "${sources.cgroup-exporter}/nix/package.nix" { };
        };
      };
    };
    networking.firewall.interfaces.wt0.allowedTCPPorts = [ cfg.port ];
  };
}