infrastructure/modules/nixos/dgn-cephfs.nix

# SPDX-FileCopyrightText: 2024 Ryan Lahfa <ryan@dgnum.eu>
# SPDX-FileContributor: Elias Coppens <elias@dgnum.eu>
#
# SPDX-License-Identifier: EUPL-1.2

{
  meta,
  pkgs,
  config,
  lib,
  ...
}:
let
  inherit (lib)
    mkEnableOption
    mkIf
    types
    mkOption
    concatStringsSep
    ;
  cfg = config.dgn-cephfs;
in
{
  options.dgn-cephfs = {
    enable = mkEnableOption "the CephFS module for our hypervisors";
    fsid = mkOption {
      type = types.str;
    };
    initialMembers = mkOption {
      type = types.attrsOf types.str;
      default = { };
      example = {
        "hypervisor01" = "10.0.0.254";
        "hypervisor02" = "10.0.0.253";
      };
    };
  };

  config = mkIf cfg.enable {
    networking.firewall.allowedTCPPorts = [
      6789
      3300
    ];
    networking.firewall.allowedTCPPortRanges = [
      {
        from = 6800;
        to = 7300;
      }
    ];
    environment.systemPackages = [
      pkgs.ceph
      pkgs.gdb
    ];
    environment.enableDebugInfo = true;
    services.ceph = {
      enable = true;
      global = {
        inherit (cfg) fsid;
        monInitialMembers = concatStringsSep ", " (builtins.attrNames cfg.initialMembers);
        monHost = concatStringsSep ", " (builtins.attrValues cfg.initialMembers);
        # TODO: change it
        clusterName = "ceph";
        clusterNetwork = "10.0.254.0/24";
        publicNetwork = "10.0.254.0/24";
      };

      extraConfig.public_addr = builtins.head meta.network.${config.networking.hostName}.addresses.ipv4;
      osd = {
        enable = true;
        daemons = [ config.networking.hostName ];
      };

      mon = {
        enable = true;
        daemons = [ config.networking.hostName ];
      };

      mgr = {
        enable = true;
        daemons = [ config.networking.hostName ];
      };
    };
  };
}