infrastructure/machines/nixos/compute01/extranix/default.nix

# SPDX-FileCopyrightText: 2024 Lubin Bailly <lubin.bailly@dgnum.eu>
#
# SPDX-License-Identifier: EUPL-1.2

{
  lib,
  pkgs,
  meta,
  bootstrap,
  sources,
  dgn-keys,
  ...
}:
let
  inherit (lib.extra) mkImports;
  host = "search.infra.dgnum.eu";
in
{
  services = {
    nginx.virtualHosts.${host} = {
      enableACME = true;
      forceSSL = true;
    };

    extranix = {
      enable = true;

      theme = pkgs.fetchFromGitea {
        domain = "git.dgnum.eu";
        owner = "DGNum";
        repo = "extranix-theme";
        rev = "99e14ca818fb1f664a2221e1cc8394325426b446";
        hash = "sha256-mDa03Y3Lf/piBzxTyiNj/8OI2rYEW5Pn99lXVL9EQmg=";
      };

      modules = {
        "netconf" = {
          paths = mkImports bootstrap.root [
            "modules/netconf"
            "modules/generic"
            "lib/netconf-junos"
          ];
          path-translations = [
            {
              base = bootstrap.root;
              url = "https://git.dgnum.eu/DGNum/infrastructure/src/branch/main/";
            }
          ];
        };
        "DGNum Infrastructure" =
          let
            # prefer a non-patched nixpkgs
            infra-nixpkgs = bootstrap.pkgs;
            infra-modulesPath = "${infra-nixpkgs.path}/nixos/modules/";
          in
          {
            paths = mkImports bootstrap.root [
              "modules/generic"
              "modules/nixos"
            ];
            ignored-modules = (import "${infra-modulesPath}/module-list.nix") ++ [
              "${sources.agenix}/modules/age.nix"
              "${sources.arkheon}/module.nix"
              "${sources."microvm.nix"}/nixos-modules/host"
              "${sources.cgroup-exporter}/nix/module.nix"
              { system.stateVersion = "25.05"; }
            ];
            specialArgs = {
              inherit meta sources;
              modulesPath = builtins.storePath infra-modulesPath;
              pkgs = infra-nixpkgs;
              inherit (infra-nixpkgs) lib;
              name = "nodeName";
              nodeMeta = {
                nix-modules = [ ];
                admins = [ ];
                adminGroups = [ ];
              };
              dgn-keys = dgn-keys // {
                getNodeAdmins = _: [ ];
              };
            };
            path-translations = [
              {
                base = bootstrap.root;
                url = "https://git.dgnum.eu/DGNum/infrastructure/src/branch/main/";
              }
              {
                base = sources.nix-modules;
                url = "https://git.hubrecht.ovh/hubrecht/nix-modules/src/branch/main/";
              }
              {
                base = infra-modulesPath;
                url = "https://github.com/NixOS/nixpkgs/tree/master/nixos/modules";
              }
            ];
          };
      };
      inherit host;

      index = "DGNum Infrastructure";

      settings = {
        baseUrl = "https://dgnum.eu/";
        title = "DGNum module documentation";
        languageCode = "en-us";
        params = {
          logo = "images/dgnum.png";
          release_switch_title = "Category";
          footer_credits_line = ''
            Based on <a href="https://github.com/mipmip/home-manager-option-search">Home Manager Option Search</a>
          '';
          footer_copyright_line = ''
            Made by catvayor for the <a href="https://dgnum.eu">DGNum</a>.
          '';
          main_menu = [
            {
              name = ''<img src="images/forgejo.png" /> Source'';
              url = "https://git.dgnum.eu/DGNum/infrastructure/";
            }
          ];
        };
      };
    };
  };
}