chore: Abstract machines and modules

This adds subdirectories for the different types of systems, for the
modules and the machines

machines/nixos/rescue01/_configuration.nix

@@ -0,0 +1,19 @@
+{ lib, ... }:
+
+lib.extra.mkConfig {
+  enabledModules = [
+    # List of modules to enable
+    "dgn-web"
+  ];
+
+  enabledServices = [
+    # List of services to enable
+    "uptime-kuma"
+  ];
+
+  extraConfig = {
+    services.netbird.enable = true;
+  };
+
+  root = ./.;
+}

machines/nixos/rescue01/_hardware-configuration.nix

@@ -0,0 +1,41 @@
+{ lib, modulesPath, ... }:
+
+{
+  imports = [ (modulesPath + "/profiles/qemu-guest.nix") ];
+
+  boot = {
+    initrd.availableKernelModules = [
+      "ata_piix"
+      "uhci_hcd"
+      "virtio_pci"
+      "virtio_scsi"
+      "sd_mod"
+      "sr_mod"
+    ];
+    initrd.kernelModules = [ ];
+    # hack to avoid intel_kvm that is set in dgn-hardware
+    kernelModules = lib.mkForce [ ];
+    extraModulePackages = [ ];
+  };
+
+  fileSystems."/" = {
+    device = "/dev/disk/by-uuid/ed02dfb7-7071-4852-9bb6-f3bd965e0234";
+    fsType = "ext4";
+  };
+
+  fileSystems."/boot" = {
+    device = "/dev/disk/by-uuid/5781-E6CA";
+    fsType = "vfat";
+  };
+
+  swapDevices = [ ];
+
+  # Enables DHCP on each ethernet and wireless interface. In case of scripted networking
+  # (the default) this is the recommended approach. When using systemd-networkd it's
+  # still possible to use this option, but it's recommended to use it in conjunction
+  # with explicit per-interface declarations with `networking.interfaces.<interface>.useDHCP`.
+  networking.useDHCP = lib.mkDefault true;
+  # networking.interfaces.ens18.useDHCP = lib.mkDefault true;
+
+  nixpkgs.hostPlatform = lib.mkDefault "x86_64-linux";
+}

machines/nixos/rescue01/secrets/secrets.nix

@@ -0,0 +1,4 @@
+(import ../../../../keys).mkSecrets [ "rescue01" ] [
+  # List of secrets for rescue01
+  "stateless-uptime-kuma-password"
+]

machines/nixos/rescue01/secrets/stateless-uptime-kuma-password

@@ -0,0 +1,28 @@
+age-encryption.org/v1
+-> ssh-ed25519 jIXfPA wZdqi7vBlMEOJiY1VvbsmqyBSO/jl6SWLRGw+0ylKWo
+UvKyh4Jh608Z9i9+6WuPu3mwnlC98aAr6jiV38JJGzk
+-> ssh-ed25519 QlRB9Q +DUjR2Wqwg2SevBY+YgvLEDkcnoWGRTfcVFbl27CQT4
+poWQnP4cOQGc5Xhgrgz2KKEOJ8dB+iCcqME5D/zJv5c
+-> ssh-ed25519 r+nK/Q GsidIKDaPJmx8igrgoAbWGywJQB0nV/cY8Zm0CIByho
+m4HrxUhPkp7gahyLO2gfQUnglkB715jaCrADg77ns34
+-> ssh-rsa krWCLQ
+VwNy3N6+l3Vgpo8AK7cJ2gRmHa+oBtB4w3n+E8gn7sugcEB16NDtjK861zwszUq7
+OfOPUZ5mE+RWz20XYWPAJIPEYNaiqc5vJzguFvZdlyJNInJLxANlIaHydE1AGA9v
+l07t9PAxxV5L40EiPHxjveEKaKiAAJVbWWfILX9f4U5vjKy5729IE/3aTRUbTD/M
+CXINLnzFWwDLi3x2yBrGUly2mLIb4KyDuE8jnPmtCFveKsVxVsDEeiXvi0yeT+xM
+viGvXJ9Ad6tAug4BE2suqwG1iPHsa98pFBqYM8gG2rp2WOFhzs0emkTu5LGYJOMr
+VR39Qxcdp1WjPr9e+l/MDQ
+-> ssh-ed25519 /vwQcQ GBXHQzwSFS+abM91umquafIEcUoI407reSuULz7SGGY
+WpW9aHq2Eq8pXpvGsEKoByQLj0tr04GxNQrf09ronrY
+-> ssh-ed25519 0R97PA BxlIEcd6G5GDLUxgoTzyUqRRxGIx49YCZSvzjVIBdjw
+oDqUd2O+oBdDrOvrQysdptF1LuvXK/dKurFnHUjgNfk
+-> ssh-ed25519 JGx7Ng Km6PmwRZ9HfGjEhkgb8P+ZCt+B/C+jg9bcvdwBvrS0Q
+D+UC5nkMnpYuJtz5X30iF1avU+jlEy4zOEPkyj5o2x8
+-> ssh-ed25519 5SY7Kg 3tf/eLI3ngqilOfEz8fayTDHWHNd14ANJTSt5lz1yDM
+QUhDPYuiZ9YloKgYqY5UdMVmawyMAOS/T4jbpvsNJpI
+-> ssh-ed25519 p/Mg4Q h/8lvmwcmoyTa6vW0N2AbgKt/dpNNqVmRW02NaYl7Wo
+OaFeo+ZPa2LY5zRJzv/exq4bv734FxZwX3ql1kpv5bk
+-> ssh-ed25519 +MNHsw iaiHp0x4Xzf886Q0Li6IleeO3wZUAQbYFHxn0jzdCk0
+W4gaBtwKPbonB2g9+Ts+teXPEPoWDCVoVn1vixiQ+7M
+--- 1ACvcwsxZKnjgKRAzJy8e4eBtxZXrwe00wPdDlMWnBo
+Œ<ƒ¼î|ë=©r<2Ÿµ.>ÃÇ~,5J²Ä … àé[ºë^+͸Z‰ñj›á×=Ï<Ï%Út뮪

machines/nixos/rescue01/uptime-kuma.nix

@@ -0,0 +1,156 @@
+{
+  config,
+  lib,
+  nodes,
+  sources,
+  ...
+}:
+let
+  inherit (lib)
+    concatLists
+    mapAttrsToList
+    mkForce
+    mkMerge
+    ;
+
+  inherit (config.statelessUptimeKuma.lib)
+    pingProbesFromHive
+    fromHive
+    httpProbesFromConfig
+    probesWithTag
+    ;
+
+  probesCfg = config.statelessUptimeKuma.probesConfig;
+
+  mkMonitors = name: builtins.attrNames (probesWithTag { inherit name; } probesCfg);
+
+  host = "status.dgnum.eu";
+
+  port = 3001;
+
+  httpExcludes = [
+    "localhost"
+    "ens.cal.dgnum.eu"
+    "luj-current.cal.dgnum.eu"
+    "s3.dgnum.eu"
+    "cdn.dgnum.eu"
+    "saml-idp.dgnum.eu"
+    "status.dgnum.eu"
+    "radius.dgnum.eu"
+  ] ++ (concatLists (mapAttrsToList (_: { config, ... }: config.dgn-redirections.retired) nodes));
+
+  extraProbes = {
+    monitors = {
+      "prometheus.dgnum.eu" = {
+        type = mkForce "http";
+        accepted_statuscodes = [ "401" ];
+      };
+
+      "ollama01.beta.dgnum.eu" = {
+        type = mkForce "http";
+        accepted_statuscodes = [ "401" ];
+      };
+
+      "s3-admin.dgnum.eu" = {
+        type = mkForce "http";
+        accepted_statuscodes = [ "400" ];
+      };
+
+      "api.meet.dgnum.eu" = {
+        keyword = "Crab Fit API";
+      };
+    };
+  };
+
+  status_pages = {
+    "dgnum" = {
+      title = "DGNum";
+      description = "Etat de l'infra de la DGNum";
+      showTags = true;
+      publicGroupList = [
+        {
+          name = "Services";
+          weight = 1;
+          monitorList = mkMonitors "Service";
+        }
+        {
+          name = "Serveurs";
+          weight = 2;
+          monitorList = mkMonitors "Ping";
+        }
+        {
+          name = "VPN Interne";
+          weight = 2;
+          monitorList = mkMonitors "VPN";
+        }
+      ];
+    };
+  };
+
+  pingProbes = pingProbesFromHive {
+    inherit nodes;
+    mkHost = _: config: config.networking.fqdn;
+    tags = [ { name = "Ping"; } ];
+    excludes = [
+      "geo01"
+      "geo02"
+      "rescue01"
+    ];
+  };
+
+  vpnProbes = pingProbesFromHive {
+    inherit nodes;
+    prefix = "VPN - ";
+    mkHost = node: _: "${node}.dgnum";
+    tags = [ { name = "VPN"; } ];
+    excludes = [
+      "rescue01"
+      "web02"
+    ];
+  };
+
+  httpProbes = fromHive {
+    inherit nodes;
+    builder =
+      _: module:
+      httpProbesFromConfig {
+        inherit (module) config;
+        tags = [
+          {
+            name = "Host";
+            value = module.config.networking.fqdn;
+          }
+          { name = "Service"; }
+        ];
+        excludes = httpExcludes;
+      };
+  };
+in
+{
+  imports = [ (sources.stateless-uptime-kuma + "/nixos/module.nix") ];
+  nixpkgs.overlays = [ (import (sources.stateless-uptime-kuma + "/overlay.nix")) ];
+
+  services.uptime-kuma.enable = true;
+
+  dgn-web.simpleProxies.uptime-kuma = {
+    inherit host port;
+    proxyWebsockets = true;
+  };
+
+  statelessUptimeKuma = {
+    probesConfig = mkMerge [
+      pingProbes
+      httpProbes
+      extraProbes
+      vpnProbes
+      { inherit status_pages; }
+    ];
+
+    extraFlags = [ "-s" ];
+
+    host = "http://localhost:${builtins.toString port}/";
+    username = "dgnum";
+    passwordFile = config.age.secrets."stateless-uptime-kuma-password".path;
+    enableService = true;
+  };
+}