infrastructure/machines/compute01/stirling-pdf/default.nix

{ nixpkgs, ... }:

let
  ###
  # How to update:
  # - clone https://git.dgnum.eu/DGNum/Stirling-PDF
  # - switch to the branch dgn-v0.X.Y where X.Y is the version in production
  # - fetch upstream changes up to the tagged release in nixos-unstable
  # - rebase onto the upstream branch, so that the last commit is "feat: Add DGNum customization"
  # - push to a new branch dgn-v0.A.B where A.B is the new version
  # - finally, update the commit hash of the customization patch

  dgn-id = "d73e347b1cefe23092bfcb2d3f8a23903410203e";
  port = 8084;
in

{
  dgn-web.internalPorts.stirling-pdf = port;

  services.stirling-pdf = {
    enable = true;

    package = nixpkgs.unstable.stirling-pdf.overrideAttrs (old: {
      patches = (old.patches or [ ]) ++ [
        (builtins.fetchurl "https://git.dgnum.eu/DGNum/Stirling-PDF/commit/${dgn-id}.patch")
      ];
    });

    domain = "pdf.dgnum.eu";
    inherit port;

    nginx = {
      enableACME = true;
      forceSSL = true;
    };

    environment = {
      UI_APP_NAME = "DGNum PDF";
      SYSTEM_DEFAULT_LOCALE = "fr-FR";
    };
  };
}