b9c0d93670
This changes the practice for building kernel modules: now we expect that the appropriate Kconfig symbols are set to =m in config.kernel.config, and then use pkgs.kmodloader to create a service that loads and unloads all the modules depended on by a particular requirement. Note that modules won't be installed on the target device just by virue of having been built: only the modules that are referenced by a kmodloader package will be in the closure. An example may make this clearer: see modules/firewall/default.nix in this commit. Why? If you have a compiled Linux kernel source tree and you change some symbol from "is not set" to m and then run make modules, you cannot in general expect that newly compiled module to work. This is because there are places in the build of the main kernel where it looks to see which modules _may_ be defined and uses that information to accommodate them. For example in an in-kernel build of https://github.com/torvalds/linux/blob/master/net/netfilter/core.c#L689 some symbols are defined only if CONFIG_NF_CONNTRACK is set, meaning this code won't work if we have it unset initially then try later to enable it and build modules only. Or see https://github.com/torvalds/linux/blob/master/include/linux/netdevice.h#L160
137 lines
4 KiB
Nix
137 lines
4 KiB
Nix
## Kernel-related options
|
|
## ======================
|
|
##
|
|
##
|
|
|
|
{ lib, pkgs, config, ...}:
|
|
let
|
|
inherit (lib) mkEnableOption mkOption types isDerivation hasAttr ;
|
|
inherit (pkgs.pseudofile) dir symlink;
|
|
inherit (pkgs.liminix.networking) address interface;
|
|
inherit (pkgs.liminix.services) bundle;
|
|
inherit (pkgs) liminix;
|
|
|
|
type_service = pkgs.liminix.lib.types.service;
|
|
|
|
mergeConditionals = conf : conditions :
|
|
# for each key in conditions, if it is present in conf
|
|
# then merge the associated value into conf
|
|
lib.foldlAttrs
|
|
(acc: name: value:
|
|
if (conf ? ${name}) && (conf.${name} != "n")
|
|
then acc // value
|
|
else acc)
|
|
conf
|
|
conditions;
|
|
in {
|
|
options = {
|
|
kernel = {
|
|
src = mkOption { type = types.path; } ;
|
|
version = mkOption { type = types.str; default = "5.15.137";} ;
|
|
modular = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = "support loadable kernel modules";
|
|
};
|
|
extraPatchPhase = mkOption {
|
|
default = "true";
|
|
type = types.lines;
|
|
};
|
|
config = mkOption {
|
|
description = ''
|
|
Kernel config options, as listed in Kconfig* files in the
|
|
kernel source tree. Do not include the leading "CONFIG_"
|
|
prefix when defining these. Most values are "y", "n" or "m",
|
|
but sometimes other strings are also used.
|
|
'';
|
|
type = types.attrsOf types.nonEmptyStr;
|
|
example = lib.literalExpression ''
|
|
{
|
|
BRIDGE = "y";
|
|
TMPFS = "y";
|
|
FW_LOADER_USER_HELPER = "n";
|
|
};
|
|
'';
|
|
};
|
|
conditionalConfig = mkOption {
|
|
description = ''
|
|
Kernel config options that should only be applied when
|
|
some other option is present.
|
|
'';
|
|
type = types.attrsOf (types.attrsOf types.nonEmptyStr);
|
|
default = {};
|
|
example = {
|
|
USB = {
|
|
USB_XHCI_MVEBU = "y";
|
|
USB_XHCI_HCD = "y";
|
|
};
|
|
};
|
|
};
|
|
makeTargets = mkOption {
|
|
type = types.listOf types.str;
|
|
};
|
|
};
|
|
};
|
|
config = {
|
|
system.outputs =
|
|
let
|
|
mergedConfig = mergeConditionals
|
|
config.kernel.config
|
|
config.kernel.conditionalConfig;
|
|
k = liminix.builders.kernel.override {
|
|
config = mergedConfig;
|
|
inherit (config.kernel) version src extraPatchPhase;
|
|
targets = config.kernel.makeTargets;
|
|
};
|
|
in {
|
|
kernel = k.vmlinux;
|
|
zimage = k.zImage;
|
|
};
|
|
|
|
kernel = rec {
|
|
modular = true; # disabling this is not yet supported
|
|
makeTargets = ["vmlinux"];
|
|
config = {
|
|
IKCONFIG = "y";
|
|
IKCONFIG_PROC = "y";
|
|
PROC_FS = "y";
|
|
|
|
KEXEC = "y";
|
|
MODULES = if modular then "y" else "n";
|
|
MODULE_SIG = if modular then "y" else "n";
|
|
DEBUG_FS = "y";
|
|
|
|
# basic networking protocols
|
|
NET = "y";
|
|
UNIX = "y";
|
|
INET = "y";
|
|
IPV6 = "y";
|
|
PACKET = "y"; # for ppp, tcpdump ...
|
|
SYSVIPC= "y";
|
|
|
|
NETDEVICES = "y"; # even PPP needs this
|
|
|
|
# disabling this option causes the kernel to use an "empty"
|
|
# initramfs instead: it has a /dev/console node and not much
|
|
# else. Note that pid 1 is started *before* the root
|
|
# filesystem is mounted and it expects /dev/console to be
|
|
# present already
|
|
BLK_DEV_INITRD = lib.mkDefault "n"; # overriden by initramfs module
|
|
|
|
# s6-linux-init mounts this on /dev
|
|
DEVTMPFS = "y";
|
|
# some or all of these may be fix for "tmpfs: Unknown parameter 'mode'" error
|
|
TMPFS = "y";
|
|
TMPFS_POSIX_ACL = "y";
|
|
TMPFS_XATTR = "y";
|
|
|
|
FW_LOADER = "y";
|
|
FW_LOADER_COMPRESS = "y";
|
|
# We don't have a user helper, so we get multiple 60s pauses
|
|
# at boot time unless we disable trying to call it.
|
|
# https://lkml.org/lkml/2013/8/5/175
|
|
FW_LOADER_USER_HELPER = "n";
|
|
};
|
|
};
|
|
};
|
|
}
|