{ config, pkgs, lib, ... }: {

  services.nginx.virtualHosts."new.hackens.org" = {
    enableACME = true;
    forceSSL = true;
  };

  # Si tu as des problèmes un jour, vide le cache avant tout
  services.dokuwiki.sites."new.hackens.org" = {
    enable = true;
    settings = {
      template = "bootstrap3";
      license = "cc-by-sa";
      title = "hackENS";
      lang = "fr";
      breadcrumbs = 0;
      yourarehere = true;
      userewrite = 1;
      useacl = true;
      htmlok = 1;
      target._raw = ''
        array(
          'extern' => '_tab'
        );
      '';
      sitemap = 7;
      disableactions = "register";
      superuser = "@admin";
      start = "accueil";
      tpl.bootstrap3 = {
        showAddNewPage = "logged";
        fluidContainer = 0;
      };
      plugin.htmlok.htmlok=1;
    };
    pluginsConfig = {

      authad = false;
      authldap = false;
      authpdo = false;
      authmysql = false;
      authpgsql = false;
      popularity = false;

    };

    plugins = [
      (pkgs.fetchFromGitHub {
        name = "catlist";
        owner = "xif-fr";
        repo = "dokuwiki-plugin-catlist";
        rev = "147793e2b41e8cb6465df888eecfbc4ee54fb68a";
        hash = "sha256-kTL0Hm4BeWpmusLnybmBM9JPpx+ss0e/cusDHu6hH2I=";
      })
      (pkgs.php.buildComposerProject (finalAttrs: {
        pname = "commonmark";
        name = "commonmark";
        version = "1.3.1";
        composerStrictValidation = false;
        src = pkgs.fetchFromGitHub {
          owner = "clockoon";
          repo = "dokuwiki-plugin-commonmark";
          rev = "671ab735193ffb1324064ff0ddb92f63408b8580";
          hash = "sha256-0WFz71O6GLVZ1Mf5eu96cQ3t+H6F6VtlC3hNtlANwBs=";
        };
        vendorHash = "sha256-QnFdwc6IfdH98Hbm9jt6E/rO+u6I7kZqb7+hRnPra9I=";
        postInstall = ''
          rm -r $out/share
          cp -r . $out
          '';
      }))
      (pkgs.fetchFromGitHub {
        name = "htmlok";
        owner = "saggi-dw";
        repo = "dokuwiki-plugin-htmlok";
        rev = "f186dda6240c61079cd9166c1f17aabefa21c7d8";
        hash = "sha256-3s+WAb1BG2mq8+wxpQ6HgPJZ+dx6v5e+vMXaOiLYceo=";
      })
    ];
    templates = [
      (pkgs.fetchFromGitHub {
        name = "bootstrap3";
        owner = "giterlizzi";
        repo = "dokuwiki-template-bootstrap3";
        rev = "v2022-07-27";
        hash = "sha256-B3Yd4lxdwqfCnfmZdp+i/Mzwn/aEuZ0ovagDxuR6lxo=";
      })
    ];
  };

}