#  Copyright :
#  - Tom Hubrecht <tom.hubrecht@dgnum.eu>      2023
#
#  Ce logiciel est un programme informatique servant à déployer des
#  configurations de serveurs via NixOS.
#
#  Ce logiciel est régi par la licence CeCILL soumise au droit français et
#  respectant les principes de diffusion des logiciels libres. Vous pouvez
#  utiliser, modifier et/ou redistribuer ce programme sous les conditions
#  de la licence CeCILL telle que diffusée par le CEA, le CNRS et l'INRIA
#  sur le site "http://www.cecill.info".
#
#  En contrepartie de l'accessibilité au code source et des droits de copie,
#  de modification et de redistribution accordés par cette licence, il n'est
#  offert aux utilisateurs qu'une garantie limitée. Pour les mêmes raisons,
#  seule une responsabilité restreinte pèse sur l'auteur du programme, le
#  titulaire des droits patrimoniaux et les concédants successifs.
#
#  A cet égard l'attention de l'utilisateur est attirée sur les risques
#  associés au chargement, à l'utilisation, à la modification et/ou au
#  développement et à la reproduction du logiciel par l'utilisateur étant
#  donné sa spécificité de logiciel libre, qui peut le rendre complexe à
#  manipuler et qui le réserve donc à des développeurs et des professionnels
#  avertis possédant des connaissances informatiques approfondies. Les
#  utilisateurs sont donc invités à charger et tester l'adéquation du
#  logiciel à leurs besoins dans des conditions permettant d'assurer la
#  sécurité de leurs systèmes et ou de leurs données et, plus généralement,
#  à l'utiliser et l'exploiter dans les mêmes conditions de sécurité.
#
#  Le fait que vous puissiez accéder à cet en-tête signifie que vous avez
#  pris connaissance de la licence CeCILL, et que vous en avez accepté les
#  termes.

{ config, lib, ... }:

let
  inherit (lib)
    mkOption
    types
    mkEnableOption
    mkIf
    ;

  cfg = config.lab-routexp;
in

{
  options.lab-routexp = {
    enable = mkEnableOption "Routing experimentation settings.";
    connections = mkOption {
      type = types.listOf types.int;
      default = { };
      description = "Interface -> Address/CIDR map";
    };
    id = mkOption {
      type = types.int;
      description = "machine id";
    };
  };

  config = mkIf cfg.enable {
    virtualisation.proxmox = {
      node = "krz01";
      autoInstall = true;
      vmid = 150 + config.lab-routexp.id;
      bios = "ovmf";
      memory = 4096;
      cores = 2;
      net =
        [
          {
            model = "virtio";
            bridge = "vmbr1";
            tag = 2520;
          }
        ]
        ++ builtins.map (vlan: {
          model = "virtio";
          bridge = "vmbr1";
          tag = vlan;
        }) cfg.connections;
      scsi = [ { file = "zfs-noraid:16"; } ]; # This will create a 16GB volume in 'local'
    };

    systemd.network = {
      networks =
        builtins.listToAttrs (
          lib.imap0 (i: vlan: {
            name = "20-ens${builtins.toString (20 + i)}";
            value = {
              name = "ens${builtins.toString (20 + i)}";
              address = [ "fdfd:1794:0:${builtins.toString vlan}::${builtins.toString cfg.id}/64" ];
            };
          }) cfg.connections
        )
        // {
          "20-babel-local" = {
            name = "babel-local";
            address = [ "fdfd:1794::${builtins.toString cfg.id}/64" ];
          };
        };
      netdevs = {
        "babel-local" = {
          netdevConfig = {
            Name = "babel-local";
            Kind = "dummy";
          };
        };
      };
    };
  };
}