{ pkgs, nixpkgs, ... }:

let
  dgn-id = "5891e1bbda792e0546f8d785cdd4d3f570a01579";
in

{
  services.stirling-pdf = {
    enable = true;

    package = nixpkgs.unstable.stirling-pdf.overrideAttrs (old: rec {
      version = "0.26.1";

      src = pkgs.fetchFromGitHub {
        owner = "Stirling-Tools";
        repo = "Stirling-PDF";
        rev = "v${version}";
        hash = "sha256-msxP2n8Varc7/h9RVwYRBuD253JZu6/p7zQC1lmNmqc=";
      };

      deps = old.deps.overrideAttrs (_: {
        patches = [
          ./01-spotless.patch
          ./05-java-output-test.patch
        ];

        doCheck = false;
        outputHash = "sha256-i2PJmsuJ8jqTUNwj4HoiWynaK4LlLrqjIZ67rSSYypc=";
      });

      patches = [
        ./01-spotless.patch
        ./02-propsfile.patch
        ./03-jar-timestamps.patch
        (pkgs.substituteAll {
          src = ./04-local-maven-deps.patch;
          inherit deps;
        })
        ./05-java-output-test.patch
        (builtins.fetchurl "https://git.dgnum.eu/DGNum/Stirling-PDF/commit/${dgn-id}.patch")
      ];
    });

    domain = "pdf.dgnum.eu";
    port = 8084;

    nginx = {
      enableACME = true;
      forceSSL = true;
    };

    environment = {
      UI_APP_NAME = "DGNum PDF";
      SYSTEM_DEFAULT_LOCALE = "fr-FR";
    };
  };
}